I quickly got to work:

#!/usr/bin/perl
use strict;
use warnings;
use Sendmail::PMilter;
my $conn = 'local:/var/run/mymilter.sock';
my $milter = Sendmail::PMilter->new();
$milter->setconn($conn);
$milter->register('mymilter',
                  {}
                  Sendmail::PMilter::SMFI_CURR_ACTS
                 );
$< = $> = getpwnam 'nobody';
$milter->main()
[download]

First thing - Postfix wasn't connecting. Without being able to waste a bunch of time here, I just changed $conn to 'inet:33333@127.0.0.1'. Problem solved - connections started happening.

So far, so good. So I went and added in my filter. In my case, I wanted toensure that the destination address for each email actually was a valid host name. So I had:

$milter->register('mymilter',
                  {
                      envrcpt => \&my_envrcpt_callback,
                  },
                  Sendmail::PMilter::SMFI_CURR_ACTS
                 );
openlog 'mymilter', 'pid', Unix::Syslog::LOG_MAIL();
[download]

and up top:

use Unix::Syslog qw(:macros :subs);
sub is_valid_host
{
    my $host = shift;
    return undef unless $host;
    my ($name,$aliases,$addrtype,$net) = gethostbyname($host);
    defined $name;
}

sub my_envrcpt_callback
{
    my $ctx = shift;

    my $rcpt_addr = $ctx->getsymval('{rcpt_addr}');
    my ($fqdn) = ($rcpt_addr =~ /\@(\S+)/);

    if (not is_valid_host($fqdn))
    {
        # no such machine?
        syslog LOG_INFO, "$$: Rejected mail for $fqdn";

        return Sendmail::PMilter::SMFIS_ACCEPT;
    }

    Sendmail::PMilter::SMFIS_ACCEPT;
}
[download]

Seems pretty straight-forward, right? As you can see, I was accepting even the failures, but that was because I was testing still. Once I saw the syslog with correct entries, I changed that to SMFIS_REJECT, and suddenly email started dropping. Beautiful. However, there were still a few issues. First off, checking hosts is a network operation, and thus can be slow. Since these don't change often (it's a home network), I figured a bit of caching could help:

my %cache;
sub is_valid_host
{
    my $host = shift;
    return undef unless $host;

    $host = lc $host;
    unless (exists $cache{$host})
    {
        my ($name,$aliases,$addrtype,$net) = gethostbyname($host);
        $cache{$host} = $name;
    }
    $cache{$host};
}
[download]

This sped things up noticeably. (Though if the dns server is on the same machine, this is probably negligible - I'm just not sure I'll always have the email and the dns on the same machine, and my testing of this code on a different machine showed this problem.) Normally, I don't bother with minor performance issues, but 100's of DNS queries per minute seemed like a candidate, even though the problem was larger in test than it would be in production.

The next issue was how the dozen or so child processes were being used. Sendmail::PMilter automatically spawned off subprocesses like any good daemon should, and I just wondered if I really needed them, and how they were being used. I had no idea. So I created a global $msg_count, set to 0, and in my_envrcpt_callback, simply did this:

        ++$msg_count;
        $0 = "[mymilter:$msg_count@" . scalar(localtime) . "] Checking
+ $fqdn ($rcpt_addr)";
[download]

Now I could see utilisation (or a reasonable facsimile thereof) via ps. I noticed that only about 3 or 4 processes were handling all the requests. This seemed odd to me. I tried one of Sendmail::PMilter's other dispatchers by setting $ENV{PMILTER_DISPATCHER} = 'prefork'; at the top of the script. Suddenly, the processes were being more evenly used. And fewer processes, mind you. It seemed also (from uptime) that I was using less CPU, so I stuck with it.

However, then I found that my milter stopped responding to Postfix after a while. I couldn't figure out why, so I added an "alarm 30" to the top of my_envrcpt_callback (if I stop hearing from postfix for 30 seconds, tell me, and reset each time I get an email to look at). And I added a global $ENV{ALRM} = sub { die "alarm\n" };.

And now this is what I have:

#!/usr/bin/perl
use strict;
use warnings;

use Sendmail::PMilter;
use Unix::Syslog qw(:macros :subs);

my $conn = 'inet:33333@127.0.0.1';
$ENV{PMILTER_DISPATCHER} = 'prefork';

my %cache;
sub is_valid_host
{
    my $host = shift;
    return undef unless $host;

    $host = lc $host;
    unless (exists $cache{$host})
    {
        my ($name,$aliases,$addrtype,$net) = gethostbyname($host);
        $cache{$host} = $name;
    }
    $cache{$host};
}

$SIG{ALRM} = sub { die "alarm\n" };

{
    my $msg_count = 0;
    sub my_envrcpt_callback
    {
        my $ctx = shift;

        # if we're not used in 30 seconds, quit.
        alarm 30;

        my $rcpt_addr = $ctx->getsymval('{rcpt_addr}');
        my ($fqdn) = ($rcpt_addr =~ /\@(\S+)/);
        ++$msg_count;
        $0 = "[mymilter:$msg_count@" . scalar(localtime) . "] Checking
+ $fqdn ($rcpt_addr)";

        if (not is_valid_host($fqdn))
        {
            # no such machine?
            syslog LOG_INFO, "$$: Rejected mail for $fqdn";

            return Sendmail::PMilter::SMFIS_REJECT;
            #return Sendmail::PMilter::SMFIS_ACCEPT;
        }

        Sendmail::PMilter::SMFIS_ACCEPT;
    }
}

my $milter = Sendmail::PMilter->new();
$milter->setconn($conn);
$milter->register('mymilter',
                  {
                      envrcpt => \&my_envrcpt_callback,
                  },
                  Sendmail::PMilter::SMFI_CURR_ACTS
                 );

openlog 'mymilter', 'pid', Unix::Syslog::LOG_MAIL();

$< = $> = getpwnam 'nobody';

syslog LOG_INFO, "Starting up: $$";

END { closelog }

$milter->main(10,100);
[download]

And it seems to be working. My cron job is still running, but deals with a minor amount of email (addressed to a real host, but no user by that name there - gets rejected there, comes back to the mail server, but can't get back out dueto the block above) relatively speaking. I now have a bit of infrastructure set up such that I could find a way to validate the destination email address and reject immediately if I find the need/time. Not sure how, yet, but we'll see.