http://qs321.pair.com?node_id=692745

This is a brief summary of code that I've found to send UTF-8 Unicode e-mails that can be sent through SMTP servers that only support 7-bit encoding.

Creating UTF-8 Formatted E-mail Using MIME::Entity

Many SMTP servers will not permit 8-bit characters. UTF-8 encoding requires 8-bit support because the high bit of the first byte is used to indicate successive bytes forming part of the same character.

Assume you have some text containing unicode. For example:

my $data = "Goodbye in Japanese is \x{3055}\x{3088}\x{306A}\x{3089}.";

[download]

When creating an e-mail use the "quoted-printable" form of encoding for the data which will correctly encode the UTF-8 characters into 7-bit form. E-mail headers, however, must be encoded in the "MIME-Header" form if they contain any UTF-8 characters (which would often be in the case of foreign language subject headings).

The 7-bit version of the e-mail is obtained using the stringify function.

use Encode;
use MIME::Entity;

my $entity = MIME::Entity->build(
    Type => "text/plain",
    Charset => "UTF-8",
    Encoding => "quoted-printable",
    Data => Encode::encode( "UTF-8", $data ),
    From => Encode::encode(
        "MIME-Header", $sender
    ),
    To => Encode::encode(
        "MIME-Header", $recipient
    ),
    Subject => Encode::encode(
        "MIME-Header", $subject
    ),
);

[download]

Sending the Encoded Message Using Net::SMTP

Next, it is a relatively trivial matter of sending the appropriately coded message to a SMTP server (using Net::SMTP):

use Net::SMTP;

my $smtp = Net::SMTP->new(
    "localhost",
    Hello => 'localhost.localdomain',
    Timeout => 15,
    Debug => 1,
);
$smtp->mail( $sender );
if ( $smtp->recipient( $recipient ) ) {
    $smtp->data();
    my $msg = $entity->stringify;
    while ( $msg =~ m/([^\r\n]*)(\r\n|\n\r|\r|\n)?/g ) {
        my $line = ( defined($1) ? $1 : "" ) . "\r\n";
        $smtp->datasend( $line );
    }
    if ( $smtp->dataend() ) {
        print( STDERR, "Message sent!\n" );
    } else {
        print( STDERR, "Failure sending data.\n" );
    }
} else {
    print( STDERR, "Rejected recipient.\n" );
}
$smtp->quit();

[download]

See Also

Update: corrected formatting.

Replies are listed 'Best First'.
Re: Sending a UTF-8 (Unicode) E-mail
by Anonymous Monk on Jun 16, 2014 at 02:11 UTC

    I tried to add a date and a reply-to header. The date worked but not the reply-to. In strict, the reply-to throws an error 500 (can't have "reply" as stand alone word) and in non-strict, it just doesn't add it.

    Do you know how to solve this issue? Are there more complete examples out there? So far, this page was the best to solve my accents problems in the headers. Utf-8 characters were not causing problems in the message body.

    thanks,

    Serge.

[reply]
      Hi, I'm not fully up-to-date on the issue, but I did have this note in my archives, which I can't find the original source, but here it is: 
        Non USASCII characters *in headers* require special encoding:
  
  1)
   use Encode;
   $x="....";
   $x_for_header = Encode::encode('MIME-Q', $x);
   
    MIME-Q is the best for mostly USASCII strings
    MIME-B is the best for mostly non USASCII strings
   
    2) 
    Add one extra header to *fully* declare body encoding:
    print MAIL "Content-Transfer-Encoding: 8bit\n";

      [download]
      Hope it helps.
      I'm not really a human, but I play one on earth.
      Old Perl Programmer Haiku ................... flash japh
[reply]
[d/l]

Back to Meditations