There's File::Spec for doing this kind of thing portably. Most of the time, I just use slashes "as appropriate". Any path I have in a variable normally does not have a trailing slash. If it does, I consider that a special case, and it ends up eating part of my mind as I put effort into remembering it all the time. I suspect, however, that I just don't run into this kind of problem as often as you do, so I haven't come up with any practice that I'd swear by.

use File::Spec::Functions qw(catfile);

my $file = catfile(qw/ foo bar baz bax.txt /);
[download]

Have you looked at Path::Class? If not you definately should check it out. I haven't used it much myself yet, but it looks nice and has great reviews at CPAN.

Under the cover it uses File::Spec so it is portable. Here's an example using it on Windows:

use Path::Class;

my $path = file('', qw[ foo bar baz baz.txt ]);
# The '' is to make it absolute. See comment in the doc.

print $path, "\n";
print $path->as_foreign('Unix'), "\n";

__END__
\foo\bar\baz\baz.txt
/foo/bar/baz/baz.txt
[download]

lodin

sub abspath {
    # split anything that looks like a unix path seperator            
+          
    my @tokens = map { defined $_ and split /\/+/ } @_;
    @tokens = grep { $_ ne '' } @tokens;
    return join( '/', '', @tokens );
}
[download]

I also <3 File::Spec. If you want to know how to clear a path on the other hand, I suggest roaring, "I'll show you the life of the mind!"

What I do for local, unix-only hackery is: I never include a trailing slash on directories, and always build up new paths with double-quoted strings.

A typical script might look something like this:

use Env qw( $HOME );
use File::Path qw( mkpath );
use File::Basename qw( basename dirname fileparse );
use File::Copy qw( move copy );

my $some_file = shift;
my $basename = basename( $some_file );
my $backup_location = "$HOME/backups";
mkpath( $backup_location ) unless -d $backup_location;

my $new_file = "$backup_location/$basename.bak";

copy("$some_file", "$new_file") or die "got problems: $!";
[download]

My personal opinion is that doing things like this is a win for readability:
my $new_file = "$backup_location/$basename.bak";

Also, note the stack of "use"s at the top... it's hard to do anything The Right Way in perl without leaning on the standard library a lot. These days I use script templates that include a dozen "use"s by default, so I don't have to try to remember what module "fileparse" is hidden inside of, and so on.

#!/usr/bin/perl

use strict;
use warnings;
use File::Util;
use File::Copy "copy";

my ($f) = File::Util->new();
$f->make_dir('foo/bar/baz', '--if-not-exists');
copy('baz.txt', 'foo/bar/baz') or die "Copy failed: $!";
[download]