How to read from a file (The cmd-line way):
prompt> perl -we '@filecontents =<>' filename

How to read from a file (The script way):

#!/usr/bin/perl -w
use strict;
open FILEHANDLE, "< filename" 
    or die "Failed to open 'filename', $!";
my @contents = <FILEHANDLE>;
close FILEHANDLE;
[download]

#!/usr/bin/perl -w
use strict;
use IO::File;
my $file = IO::File->new( "< filename" )
    or die "Failed to open 'filename', $!";
my @contents = <$file>;
$file->close();
[download]

#!/usr/bin/perl -w
use strict;
use IO::File;
use constant FILENAME => filename;

my $file = IO::File->new( "< ". FILENAME )
    or die "Failed to open '@{[FILENAME ]}', $!";
my @elements;
{
    local $/ = $/.$/;
    @elements = <$file>;
}
$file->close();
[download]

When our student friend turns in his assignment he should be sure to add single quotes around filename on line number 4.

He should also add comments explaining what is going on and add some code to print out the array values. A final result (containing the obfuscatory dereferenced reference) is thus:

#!/usr/bin/perl -w
use strict;
use IO::File;
use constant FILENAME => 'filename'; #Replace filename with name of in
+put file.

my $file = IO::File->new( "< ". FILENAME ) 
   
    or die "Failed to open '@{[FILENAME ]}', $!"; # Dereferenced array
+ ref and OS error
        
my @elements;
{
    local $/ = $/.$/; #Replace default input delimeter (\n) with (\n\n
+)
    @elements = <$file>;
}
$file->close();

#Now test to see that everything reads out okay
print "Here are the elements of the array:\n";
for (my $i = 0; $i < @elements; $i++) {
    print "Element number $i of the array is:\n$elements[$i]\n";    
}
[download]

If our friend makes some effort to understand what he has submitted then he will have learned his lesson well. Maybe we will see him here with Tye and Merlyn someday.

Good catch on the quotes around the filename. I intentionally left it all uncommented. But lets have some more fun with it:

#!/usr/bin/perl -w
use strict;
use IO::File;
use constant FILENAME => 'filename';

{
  package cntr;
  sub TIESCALAR{bless[pop],__PACKAGE__} 
  sub FETCH{ $_[0][0]++ } 
}

my $file = IO::File->new( "< ". FILENAME )   
    or die "Failed to open '@{[FILENAME]}', $!"; 
        
my @elements;
{
    local ( $a, $/ ) = $/.$/;
    @elements = split $a => <$file>;
}
$file->close();

print "Here are the elements of the array:\n";

tie my $i, 'cntr', 1;
print map {$i.': {'."$_}$/"} @elements;
[download]

Yeah, that would go over well with a teacher or professor.

Update: So I changed the code a little from the original post. I actually tested it, and didn't like the way the newlines hung around. This fixes that. View source for the old code.

$/ = "\n\n"; # Sets the input record separator to two newlines
my @array = <FILE>; # Put the file in an array
$/ = "\n"; # Sets the input record separator to one newline (the defau
+lt)
[download]

#!/usr/bin/perl 
 
use strict; 
 
my $file='mydata.txt'; 
my %hash; 
 
open IN,$file || die $!; 
 
my $key; 
 
while (<IN>) { 
  ## remove the end-o-line 
  chomp; 
  ## blank line means a new recipe 
  if (/^\s*$/) { 
    undef $key; 
    next; 
  } 
  ## stuff the key with something 
  if (! defined $key) { 
    $key=$_; 
    next; 
  } 
  ## okay, split the line and add the parts 
  push @{$hash{$key}},split /\s{2,}/,$_; 
} 
 
close IN; 
 
for my $key (sort keys %hash) { 
  print "'$key' is made with: ".join(",",@{$hash{$key}})."\n"; 
}
[download]

$a = supersplit('/[\s\n]+/','\n\n',"/my/flat/file/");
[download]

Jeroen
"We are not alone"(FZ)

--
$Stalag99{"URL"}="http://stalag99.keenspace.com";