Here's a little module that I just threw together. It overrides the builtin time sub (Update: and also localtime and gmtime) to adjust the output by some offset:

package TimeOffset;

sub import {
    my $pkg = shift;
    my $offset = shift || "+0";

    if ($offset !~ /^[+-]/) {
       $offset = $offset - time;
    }

    *CORE::GLOBAL::time = sub { CORE::time() + $offset };

    *CORE::GLOBAL::localtime = sub {
       return @_ ? CORE::localtime(@_)
                 : CORE::localtime(CORE::time() + $offset);
    };

    *CORE::GLOBAL::gmtime = sub {
       return @_ ? CORE::gmtime(@_)
                 : CORE::gmtime(CORE::time() + $offset);
    };
}

1;
[download]

use TimeOffset '+3600'; # pretend it's 1hr in the future
[download]

use TimeOffset '-60'; # pretend it's 1min in the past
[download]

use TimeOffset 12345678; # pretend the program was started
                         # at 12345678 epoch seconds
[download]

Perhaps I could make this a little nicer, package it up, and send it off to CPAN? That is, if something like this really isn't on CPAN already..

Update: some caveats that I can think of, off the top of my head:

• doesn't affect -M, -A, -C filetest operators in the way you'd probably want. I belive these would still report *actual* script start time (not faked script start time) minus file access time.

This looks more like what I was getting at. Thanks. I'd say package it up, I'd have used it if it were there this morning. The competition requires a compile.

- d

Very nice... A couple extra ideas, which may or may not already be in the changes you made before sending it to CPAN:

- Change $offset from my to our (or add a method for setting it) so that tests can, e.g., do something now (at an offset of +0) which expires in an hour, then set offset to +3600 and check whether it has expired.

- Add an our $fixed_time which, if defined, returns that time (instead of actual time + offset) for all calls. This would be useful for cases where you're testing that a sub stores the time correctly and don't want to have to worry about whether the system clock rolled over from 12345678 to 12345679 between when the time is stored and when you test the stored value's correctness.

Well, that's sorta like what I was thinking.. The problem is that I can't make something like mytime() and replace throughout the code because A> waaaay too many to replace, and B> it's an internal codebase change. The testing system has to fake the time externally to validate the code, otherwise it would be modified again when I take out the test..

My first thought was to try using something like this:

package FakeTime;
sub main::time { 12345 }
1;
[download]

That didn't work. Neither did "sub ::time { 12345 }", I thought that might work as a second resort. Didn't.

- d