The eq operator is for comparing strings. Using it in a context other than a comparison (like you've done correctly with your if and elsifs there) doesn't make much sense because it doesn't do anything other than return a true or false value in and of itself (which is why you're being warned that it's useless).

Guessing from the context you're trying to assign something to $cust so you want the assignment operator = instead: $cust = 'SMC';.

Update: And a bit more of a better long term solution would be to look into one of the standard argument parsing modules like Getopt::Long and use that instead of trying to cobble together your own.

Another thing: I notice you give your option in your sample command line as -fet all lower case but you're comparing against -FET. String comparisons are case sensitive so that's not going to match (and even Getopt::Long wouldn't help you here). Pick a case and stick with it, or use lc (or uc) to canonicalize everything to one or the other before you attempt to compare them.

I could be wrong, but this smells like a good opportunity to learn about Getopt::Long. I tend to use it with the hashref method like this.

    use Getopt::Long;
    my $opts = {};

    #
    # maybe set some overridable defaults...
    #
    $opts->{target} = 'foo';
    $opts->{cust}   = 'SMC';

    GetOptions( $opts,
                    'target=s',
                    'cust=s',
                    'cotime=s',
    );
[download]

Now, if you type your_script.pl --target bar --cust FET --cotime baz then your $opts hashref will be populated accordingly. $opts->{target} will be 'bar', $opts->{cust} will be FET, $opts->{cotime} will be 'baz'. Setting defaults as I've demonstrated allows you to skip some of the command line args.

and depending what has been written there, alter a variable:

...
if ($ARGV[1] eq '-SMC') {$cust eq "SMC";}
...
[download]

You don't alter, you are comparing, twice. It's the second comparison ($cust eq "SMC") which leads to the warning. You mean:

if ($ARGV[1] eq '-SMC') {$cust = "SMC";}
[download]

But I guess for what you want, this is enough:

#!/usr/local/bin/perl -w
use strict;
my($target, $cust, $cotime) = @ARGV;

$cust =~ s/^-//; # strip leading dash
[download]

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}

$cust = (split(/-/, $ARGV[1]))[1];
[download]

That may admit bogus customers that don't exist, or that the program cannot deal with. It may be wiser to spell out exactly what is legal.

(my $cust = $ARGV[1]) =~ s/^-(SMC|SBM|FET|China)$/$1/
    or die "garbage in second arg: <$ARGV[1]>\n";
[download]

• another intruder with the mooring in the heart of the Perl

use strict;
use warnings;

my ( $target, $cust, $cotime ) = @ARGV;

my %lookup = (
   q{-SMC}   => q{SMC},
   q{-FET}   => q{FET},
   q{-China} => q{China},
   q{-SBM}   => q{SBM},
   );

if ( exists $lookup{ $cust } )
{
    $cust = $lookup{ $cust };
    print qq{Customer set to $cust\n};
}
else
{
    warn qq{Customer $cust not recognized\n};
}
[download]

I hope this is of use.

Cheers,

JohnGG

I had somewhere concluded that = was for numbers only

Mixing up with comparison operators. It is == that is for numbers, rather than eq for strings.

use feature qw(say switch);

given($ARGV[1]) {
    when ('-SMC') { $cust= 'SMC';  }
    when ('-FET') { $cust= 'FET''; }
     # .... add other conditions ...
     # You can even use Regular expressions (Smart match) here, if nec
+essary like:::
    when (/china/i) {$cust='China';}

    default  { say 'Invalid customer'; }
}
[download]

#!/usr/local/bin/perl -w
use strict;
my($target, $cust, $cotime) = @ARGV;

if ($ARGV[1] eq '-SMC') {
    $cust = "SMC";
}
elsif ($ARGV[1] eq '-FET') {
    $cust = 'FET';
}
elsif ($ARGV[1] eq '-China') {
    $cust = 'China';
}
elsif ($ARGV[1] eq '-SBM') {
    $cust = 'SBM';
}
[download]