Re: Converting code to use DATA filehandle instead of external templates

(Update, per haoess below) ~~First of all, the DATA filehandle begins after the __DATA__ token, not __END__~~. Here's one example to do it.

$ cat /tmp/html-data.pl
#!/usr/bin/perl

use strict;
use warnings;
use HTML::Template;
use File::Basename;

my($script, $path) = fileparse($0);

# the use of load_page() is intentional
my $template = load_page(\*DATA);
$template->param(
    script => $script,
    path => $path,
    pid => $$,
);

print $template->output;

sub load_page {
    my $fh = shift;
    HTML::Template->new(filehandle => $fh);
}

__DATA__
Hi, I'm script <tmpl_var name=script>,
located at <tmpl_var name=path>
running with process id <tmpl_var name=pid>

$ perl /tmp/html-data.pl
Hi, I'm script html-data.pl,
located at /tmp/
running with process id 4291
[download]

Actually, you can also use the scalarref or arrayref options with DATA, such as,

my $template = load_page([<DATA>]);
sub load_page {
    my $stuff = shift;
    HTML::Template->new(arrayref => $stuff);
}
[download]

Or,

local $/ = undef;
my $template = load_page(\<DATA>);
sub load_page {
    my $stuff = shift;
    HTML::Template->new(scalarref => $stuff);
}
[download]

Open source softwares? Share and enjoy. Make profit from them if you can. Yet, share and enjoy!

Comment on Re: Converting code to use DATA filehandle instead of external templates Select or Download Code

Replies are listed 'Best First'.

Re^2: Converting code to use DATA filehandle instead of external templates
by haoess (Curate) on Nov 20, 2007 at 08:39 UTC

First of all, the DATA filehandle begins after the __DATA__ token, not __END__

perldata

__END__ behaves like __DATA__ in the toplevel script (but
not in files loaded with "require" or "do") and leaves the
remaining contents of the file accessible via "main::DATA".
[download]

$ cat data_eq_end.pl
#!/usr/bin/perl

use warnings;
use strict;

print for <DATA>;

__END__
1
2
3

$ perl data_eq_end.pl
1
2
3
[download]

-- Frank

[reply]
[d/l]
[select]


Welcome to the Monastery
	PerlMonks