use strict;
use List::Util qw(reduce);

my @data = qw ( 01 b2 01 00 b6 81 81 01 b4 0a 01 01 01 01 00 
                01 00 00 01 00 c7 82 82 01 b2 01 00 b8 );

my $index;
reduce {  if ($a eq $b && $a =~ m/81|82/) {
            print "match $a starting at index $index\n"}
          $index++;
          $b;
       } @data;
[download]

Prints:

match 81 starting at index 6
match 82 starting at index 22
[download]

Update: If you would prefer to use a for loop, you should use the range operator as below. Much cleaner to read. I guess I got carried away with the reduce.

for my $i (0 .. $#data) {
    if ( $data[$i] eq $data[$i+1] && $data[$i] =~ m/81|82/) {
        print "match $data[$i] starting at index $i\n";
    }
}
[download]

Perhaps premature optimization, but I'd recommend switching your tests around so that you only look for matches of numbers you care about:-

if ($data[$i] =~ m/^(?:81|82)$/ && $data[$i] eq $data[$i+1]) {
[download]

(Note the addition of anchors in the regex so you don't accidentally match a pair of, say, 181s.)

And if the number of numbers you're trying to matches is likely to grow or change often, it may be easier using a hash instead of a regex:-

my %wanted = map { $_, 1 } qw(
    81
    82
);

# ...

for my $i (0 .. ($#data - 1)) {
    if (exists $wanted{$data[$i]} && $data[$i] eq $data[$i+1]) {
[download]

    --k.

my @data = qw( 01 b2 01 00 b6 81 81 01 b4 0a 01 01 01 01
               00 01 00 00 01 00 c7 82 82 01 b2 01 00 b8 );

for ( 1 .. $#data ) {
    if ( $data[$_] =~ /(8[12])/ and $data[$_] eq $data[$_-1] ) {
        print "Match $1 ending at index $_\n";
    }
}
[download]

#!/usr/bin/perl
use strict;
use warnings;

my @data = qw ( 01 b2 01 00 b6 81 81 01 b4 0a 01 01 01 01 00
                01 00 00 01 00 c7 82 82 01 b2 01 00 b8 );

$_ = join(' ', @data);

while ( /(8[[:xdigit:]])\s+\1/g ) {
  print "Duplicate $1 found at character " . pos() . "\n";
}
[download]

bash$ superdoc.pl
Duplicate 81 found at character 20
Duplicate 82 found at character 68
[download]

# while ( /([[:xdigit:]]{2})\s+\1/g ) {
[download]

bash$ superdoc.pl
Duplicate 81 found at position 20
Duplicate 01 found at position 35
Duplicate 01 found at position 41
Duplicate 00 found at position 53
Duplicate 82 found at position 68
[download]