Help with XML Parsing

dbonneville has asked for the wisdom of the Perl Monks concerning the following question:

Hello! I'm a brand new to Perl, but not to programming.

So far, I'm able to read in and parse and XML doc to the screen, but I'm currently at a loss as what to do next. I've been searching for some help, but am a little directionless as all-things-Perl is too new for me yet. I probably passed by some good help and didn't know it already...

Here what I'm trying to do:

- Load in an XML file
- Parse the file and look for content in it (recordsets)
- Take those records that match certain criteria and
WRITE them to a new XML file on the server.
- Do this about 30 times, for different criteria, from the master XML file from the first step.

As of yet, I can't find a way to do this. I'm not looking for hand-holding, but some good info or tips or tutorials to get me going, so I can then formulate the next intelligent question.

I started from ground zero today, with utterly no knowledge of Perl. I got it running on my PC and got this far (which to me was a LOT):

#!/usr/local/bin/perl -w
use warnings;

use XML::Parser;

my $p1 = new XML::Parser(Style => 'Debug');
$p1->parsefile('test.xml');
[download]

Thanks,

Doug

Comment on Help with XML Parsing Download Code

Replies are listed 'Best First'.

Re: Help with XML Parsing
by GrandFather (Saint) on Jul 20, 2007 at 22:07 UTC

Generally XML strongly implies "use XML::Twig". However, unless the XML you want to process is very large, in this case I'd suggest XML::TreeBuilder is most appropriate. In particular take a look a the look_down method of HTML::Element. Consider:

use strict;
use warnings;
use XML::TreeBuilder;

my $xml = <<XML;
<root>
    <a attr='1'>Contents of a - 1</a>
    <b>Contents of b</b>
    <a attr='2'>Contents of a - 2</a>
    <c>Contents of c</c>
    <d>Contents of d</d>
</root>
XML

my $root = XML::TreeBuilder->new ();

$root->parse ($xml);

print "All the 'a' elements\n";
for my $elt ($root->look_down ('_tag' => 'a')) {
    print $elt->as_XML (), "\n";
}

print "All the 'b' elements\n";
for my $elt ($root->look_down ('_tag' => 'b')) {
    print $elt->as_XML (), "\n";
}

print "All the 'a' elements with attr='2'\n";
for my $elt ($root->look_down ('_tag' => 'a', 'attr' => '2')) {
    print $elt->as_XML (), "\n";
}
[download]

Prints:

All the 'a' elements
<a attr="1">Contents of a - 1</a>

<a attr="2">Contents of a - 2</a>

All the 'b' elements
<b>Contents of b</b>

All the 'a' elements with attr='2'
<a attr="2">Contents of a - 2</a>
[download]

DWIM is Perl's answer to Gödel

[reply]
[d/l]
[select]

Re: Help with XML Parsing
by un-chomp (Scribe) on Jul 20, 2007 at 21:26 UTC

XML::LibXML

#!/usr/bin/perl

use strict;
use warnings;

use XML::LibXML;

my $parser = XML::LibXML->new;

my $dom = $parser->parse_file( 'test.xml' ); # load file

my @wanted_nodes = $dom->findnodes( './/an/xpath/here' ); # select

print $_->toString for @wanted_nodes; # output
[download]

merlyn

using XML::LibXML with HTML

[reply]
[d/l]

Re^2: Help with XML Parsing

by dbonneville (Acolyte) on Aug 23, 2007 at 15:45 UTC

Thanks! I got XML::LibXML working just fine! I was able to use XPath to get the info out of the master XML, and then print new XML files. Works like a charm.

[reply]

Re: Help with XML Parsing
by CountZero (Bishop) on Jul 20, 2007 at 21:10 UTC

Some Perl modules which can do this are XML::XSLT (does not yet fully implement all XSLT-functions), XML::Sablotron (needs a separate install of Sablotron) or XML::LibXSLT (needs access to the Gnome project libxslt library).

XML::Sablotron is probably your best bet. I remember having installed it some years ago in an Apache webserver on Windows and it worked flawless.

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

[reply]

Re^2: Help with XML Parsing

by Jenda (Abbot) on Aug 04, 2007 at 18:58 UTC

That is if you're a masochist. Fiddling with XSLT, especially if you need 30 different conditions for the filtering is definitely going to be lots of fun. Transforming XML into XML using XML containing commands in XML and snippets of XML to XML xml the xml in xml xmling the Xml xML xml xml mxml xmls xml xml xml xml </xml>

Jenda
Support Denmark!
Defend the free world!

[reply]

Re: Help with XML Parsing
by runrig (Abbot) on Jul 20, 2007 at 20:39 UTC

XML::Twig

[reply]

Re: Help with XML Parsing
by mirod (Canon) on Jul 20, 2007 at 21:58 UTC

If your criteria can be expressed using XPath, then you might be able to use xml_grep2, a tool based on XML::LibXML that you can find at http://xmltwig.com/tool/.


"be consistent"
	PerlMonks