@arr1 = qw(Sun Moon Venus Pluto Neptune);
[download]

@arr1 = ("Sun", "Moon", "Venus", "Pluto", "Neptune");
[download]

if ((grep {$_ eq 'Sun'} @arr1) && (grep {$_ eq 'Moon'} @arr1)) {
    print "We have both a sun and a moon - yay!\n";
}
else {
    print "Something is missing...\n";
}
[download]

Now I need to find out with the help of grep if the array

[snip]

I am actually looking for the above queries solution in single statement.

A few considerations:

• please stop friggin' putting your posts in pre tags: they're discoraged at the Monastery and certainly not useful here to present some simple text;
• nobody seems to have noticed yet, but why do you insist that you "need" to use grep and that you want a single statement? This strongly smells like homework!
• Thanks to stuff like do, quite about anything in Perl can be a "single statement".

To illustrate the last point, the following does use grep and is a single statement:

print "ok\n" if 2 == grep sub {
    my $x=shift;
    $_ eq $x and return 1 for @arr1;
    0;
}->($_), qw/Sun Moon/;
[download]

use strict;
use warnings;

my @source = qw(Sun Moon Pluto Venus Neptune);
my @target = @ARGV ? @ARGV : qw(Sun Moon);

print is_target_in_source(\@target, \@source), "\n";

sub is_target_in_source {
    my($target, $source) = @_; # omits arg validation
    my %target = map { $_ => 1 } @$target;
    my $in = 0;
    $target{$_} && $in++ for @$source;

    return $in == @$target ? 'Yes' : 'No';
}
[download]

But I found Array::Utils simpler to use:

use strict;
use warnings;
use Array::Utils 'intersect';

my @source = qw(Sun Moon Pluto Venus Neptune);
my @target = @ARGV ? @ARGV : qw(Sun Moon);
my @in = intersect @target, @source;
print @in == @target ? 'Yes' : 'No';
[download]

use strict;
use warnings;

my @arrays = (
   [ qw{Sun Moon Venus Pluto Neptune} ],
   [ qw{Jupiter Mercury Moon Io} ],
   [ qw{Europa Moon Ganymede Sun Earth} ],
   [ qw{Venus Sun Saturn Titan} ],
   );

my $rxSunAndMoon = qr
   {(?x)
       (?:\bSun\b(?=.*\bMoon\b))
       |
       (?:\bMoon\b(?=.*\bSun\b))
   };

foreach my $raRocks ( @arrays )
{
    print qq{Array: @$raRocks\n};
    print
       qq{@$raRocks} =~ $rxSunAndMoon
       ? qq{       Found Sun and Moon\n}
       : qq{       No match\n};
}
[download]

The output is

Array: Sun Moon Venus Pluto Neptune
       Found Sun and Moon
Array: Jupiter Mercury Moon Io
       No match
Array: Europa Moon Ganymede Sun Earth
       Found Sun and Moon
Array: Venus Sun Saturn Titan
       No match
[download]

I hope this is of interest.

Cheers,

JohnGG

                                                                      
+                                                           
#!/usr/bin/perl                                                       
+                                                                     
+                            
use strict;
use warnings;

my @arr1 = qw(Sun Moon Venus Pluto Neptune);
my @arr2 = qw(Son Moon Venus Pluto Neptune);

print "\@arr1 has both"
    if grep {/^Sun$/} @arr1
    and grep {/^Moon$/} @arr1;

print "\@arr2 has both"
    if grep {/^Sun$/} @arr2
    and grep {/^Moon$/} @arr2;
[download]

print "\@arr1 has both"
    if grep {$_ eq "Sun"} @arr1
    and grep {$_ eq "Moon"} @arr1;
[download]

Hi sroy5, try this,

use strict;
use warnings;
my @arr1  = ("Sun", "Moon", "Venus", "Pluto", "Neptune"); 
((grep/^(Sun|Moon)$/, @arr1) == 2) ? (print "True") : (print "False");
[download]

Anyway first look into these links How do I post a question effectively? & How (Not) To Ask A Question

((grep/^(Sun|Moon)$/, @arr1) == 2) ? (print "True") : (print "False");
[download]

This is not reliable if @arr1 is allowed to contain duplicates, it is deemed to give false positives and false negatives, and the OP wrote nothing about that possibility.

Oh Dang! I was going to post which would had counted the number of matches (did not post as similar method had already been shown) but I completely missed the possibility of duplicates. Thanks much.

My solution is almost like naikonta's, except I'm removing from the list of required entries instead of just counting matches. This allows you to terminate early once you've found everything required.

sub containsAll {
    my ($arrEverything, $arrRequire) = @_;
    my %stillRequired = map { $_ => 1 } @$arrRequire;
    for my $entry ( @$arrEverything ) {
        if ( delete($stillRequired{$entry}) ) {
            last unless %stillRequired;
        }
    }
    return %stillRequired ? 0 : 1;
}
[download]

Call as containsAll(\@arr1,['Sun','Moon'])

Feel free to take the concept and make it into your single statement requirement, since I don't see how anything maintainable can come of that kind of requirement.

sub isTargetInAll
{
    my ($raAll, $raTarget) = @_;
    return
       @$raTarget
       ==
       grep
       {
           exists { map { $_ => 1 } @$raAll }->{$_}
       }
       @$raTarget;
}
[download]

I think that should be reliable as long as @$raTarget doesn't contain duplicates; if you were looking for a Sun and two Moons you would get a false positive if @$raAll had a Sun and just one Moon.

Cheers,

JohnGG