Ok, lets give that "simple effective" sample code some data:

use strict;
use warnings;

my @contents = sort <DATA>;
print @contents;

__DATA__
At the moment, due to the small file size, sort time is unimportant.
At some point, when I get to that stage, the sorted data will be reuse
+d.
I tried your code, and it seems quite simple, hence, efective.
BUT, It runs with no errors, but nothing prints.
[download]

Prints:

At some point, when I get to that stage, the sorted data will be reuse
+d.
At the moment, due to the small file size, sort time is unimportant.
BUT, It runs with no errors, but nothing prints.
I tried your code, and it seems quite simple, hence, efective.
[download]

which is sorted on the whole line. It works, but ain't what you want. So lets add in some brain hurty code to sort by the "second column": :)

use strict;
use warnings;

my @contents = map { $_->[0] }
  sort { $a->[1] cmp $b->[1] }
  map { [$_, extractColumn (1, $_)] }
  <DATA>;
print @contents;


sub extractColumn {
    my ($columnIndex, $line) = @_;
    my ($key) = $line =~ /(?:[^,]*,){$columnIndex}([^,]*)/;
    return $key;
}

__DATA__
At the moment, due to the small file size, sort time is unimportant.
At some point, when I get to that stage, the sorted data will be reuse
+d.
I tried your code, and it seems quite simple, hence, efective.
BUT, It runs with no errors, but nothing prints.
[download]

Prints:

BUT, It runs with no errors, but nothing prints.
I tried your code, and it seems quite simple, hence, efective.
At the moment, due to the small file size, sort time is unimportant.
At some point, when I get to that stage, the sorted data will be reuse
+d.
[download]

However if you are dealing with csv (comma separated variable) data then you really want to be using a module such as Text::CSV to read the file. You may like to check out a few nodes that have asked the "sort CSV" question before (Super Search SoPW remember): Sorting a CSV file and sorting CSV files may help too.

I will tackle this snippet and see what happens. Thank you for your time.

use strict;
use warnings;

open (SOMELIST, "somelist") or die "Cannot open file $!\n";

my %sort_data;
while (my $record = <SOMELIST>) {
        my @one_line = split(/,/, $record);

        while (exists $sort_data{$one_line[1]}) {
                 $one_line[1] = "$one_line[1]" . " "; #add a blank for
+ uniqueness
        }
        $sort_data{$one_line[1]} = $record; #store it by 2nd column
}
close (SOMELIST);


foreach my $line (sort {$a cmp $b} keys %sort_data) {
        print "$sort_data{$line}";
}
[download]

If you find yourself "uniquifying" keys for a hash you should probably be using an array. Consider:

use strict;
use warnings;

use constant KEY => 1;

my @sort_data;
while (my $record = <DATA>) {
    my $key = (split(/,/, $record))[KEY];
    push @sort_data, [$record, $key];
}

foreach my $pair (sort {$a->[1] cmp $b->[1]} @sort_data) {
    print "$pair->[0]";
}
[download]

using the same data as in previous samples prints:

BUT, It runs with no errors, but nothing prints.
I tried your code, and it seems quite simple, hence, efective.
At the moment, due to the small file size, sort time is unimportant.
At some point, when I get to that stage, the sorted data will be reuse
+d.
[download]

---

DWIM is Perl's answer to Gödel