The following regex using lookback and look ahead assertions gets pretty close. However I don't think there is a way to distinguish between the two places where "mad?" is used except by explicit special cases.

use strict;
use warnings;

my $str = <<DATA;
The Tell-Tale HeartEdgar Allen PoeTRUE! nervous, very, very dreadfully
+ nervous I had been and am; but why WILL you say that I am mad? The d
+isease had sharpened my senses, not destroyed, not dulled them. Above
+ all was the sense of hearing acute. I heard all things in the heaven
+ and in the earth. I heard many things in hell. How then am I mad? He
+arken! and observe how healthily, how calmly, I can tell you the whol
+e story.
DATA

$str =~ s/(?<=[a-z])(?=[A-Z])|(?<=[?!.] )(?![a-z])/\n/g;

print $str;
[download]

Prints:

The Tell-Tale Heart
Edgar Allen Poe
TRUE! nervous, very, very dreadfully nervous I had been and am; but wh
+y WILL you say that I am mad? 
The disease had sharpened my senses, not destroyed, not dulled them. 
Above all was the sense of hearing acute. 
I heard all things in the heaven and in the earth. 
I heard many things in hell. 
How then am I mad? 
Hearken! and observe how healthily, how calmly, I can tell you the who
+le story.
[download]

Thank you for your time and response.

Actually single words are acceptable. I am actually cutting up larger files to be used by an ESL teaching program.

Thanks,

UH

This is as close to your desired output as I can achieve.

#! perl -slw
use strict;

( my $data = do{ local $/; <DATA> } )=~ s[\n\+][]g;

print "'$1'" while $data =~ m[
    ( .+?                        ## Capture everything (minimally)
       (?: [.!?] \s+             ## A terminator followed by whitespac
+e
         | [a-z]                 ## or a lowercase letter
       )    
    ) 
    (?= [A-Z] | \z )             ## followed by a an uppercase letter 
+or EOS
]xg;

__DATA__
The Tell-Tale HeartEdgar Allen PoeTRUE! nervous, very, very dreadfully
+ nervous I
+ had been and am; but why WILL you say that I am mad? The disease had
+ sharpened
+ my senses, not destroyed, not dulled them. Above all was the sense o
+f hearing
+ acute. I heard all things in the heaven and in the earth. I heard ma
+ny things i
+n hell. How then am I mad? Hearken! and observe how healthily, how ca
+lmly, I ca
+n tell you the whole story.
[download]

c:\test>junk5
'The Tell-Tale Heart'
'Edgar Allen Poe'
'TRUE! nervous, very, very dreadfully nervous I had been and am; but w
+hy WILL you say that I am mad? '
'The disease had sharpened my senses, not destroyed, not dulled them. 
+'
'Above all was the sense of hearing acute. '
'I heard all things in the heaven and in the earth. '
'I heard many things in hell. '
'How then am I mad? '
'Hearken! and observe how healthily, how calmly, I can tell you the wh
+ole story.
'
[download]

Which doesn't quite match, but then I do not see how (or more importantly why?) you differenciate between splitting after the question mark here I am mad? The disease but decide not to here How then am I mad? Hearken!?

Thank you very much for your response.

The explainations are very much appreciated. The resulting output is perfectably useable for my purposes.

cheers!

-UH

use strict;
use warnings;

my $rxBoundary = qr
   {(?xms)
      (?:
         (?<=[a-z])(?=[A-Z])
         |
         (?<=[.!?])(?=\s?[A-Za-z])
      )
   };

my $text = <DATA>;
chomp $text;

print
   map {qq{$_\n\n}}
   split m{$rxBoundary}, $text;

__END__
The Tell-Tale HeartEdgar Allen PoeTRUE! nervous, very, very dreadfully
+ nervous I had been and am; but why WILL you say that I am mad? The d
+isease had sharpened my senses, not destroyed, not dulled them. Above
+ all was the sense of hearing acute. I heard all things in the heaven
+ and in the earth. I heard many things in hell. How then am I mad? He
+arken! and observe how healthily, how calmly, I can tell you the whol
+e story.
[download]

and the output is

The Tell-Tale Heart

Edgar Allen Poe

TRUE!

 nervous, very, very dreadfully nervous I had been and am; but why WIL
+L you say that I am mad?

 The disease had sharpened my senses, not destroyed, not dulled them.

 Above all was the sense of hearing acute.

 I heard all things in the heaven and in the earth.

 I heard many things in hell.

 How then am I mad?

 Hearken!

 and observe how healthily, how calmly, I can tell you the whole story
+.
[download]

I hope this is of use.

Cheers,

JohnGG

split /[.!]/, $text;
[download]

Enjoy,
Mickey

So this should do the trick:

@sentences =split([.?!\L], $text);
[download]

Thank you for your help.

-UH

use warnings;
use strict;

my $SPACER = "\n\n";

while (my $line = <DATA>) {
    $line =~ s|^\s+||;  ## trim leading whitespace
    $line =~ s|\s+$||;  ## trim trailing whitespace
    $line =~ s|([.?!]+)\s*|$1$SPACER|g;       ## break at [.?!]
    $line =~ s|([a-z])([A-Z])|$1$SPACER$2|g;  ## break at camelCase
    print $line . $SPACER;
}
[download]

To focus on the flummoxing part, you're talking about whenever a lowercase letter is immediately followed by an uppercase letter (with nothing in between)?

did

@sentences=split([.!?\L], $text);
[download]

First off I think you'd need regexp slashes around the brackets to make sure you're talking about a character class, which will make sure that Perl interprets the . and ? literally. Secondly, I don't understand how \L works within a character class, especially when not followed by \E.

_________________________________________________________________________________

I like computer programming because it's like Legos for the mind.

@sents=split(/([.?!]|[:lower:]\u)/,$text);
[download]

I think the split function consumes the characters it splits on though, right, so you'd have to use $1 and append it to the previous record, then dealing with the lower/upper boundary would be even more problematic.

_________________________________________________________________________________

I like computer programming because it's like Legos for the mind.

You are partially right, split can consume the characters that it uses to split on but it is not always the case. Consider the following two code snippets

$ perl -e '
> $str = q{abcXghiXstu};
> @elems = split m{X}, $str;
> print qq{$_\n} for @elems;'
abc
ghi
stu
$ perl -e '
> $str = q{abcXghiXstu};
> @elems = split m{(X)}, $str;
> print qq{$_\n} for @elems;'
abc
X
ghi
X
stu
$
[download]

As you can see, the capturing parentheses in the regular expression of the second snippet cause split to keep the separators and assign them to the output array. So split consumes the characters only if you let it.

This behaviour does not help us with the lower/upper case split but you can see from this post that you can split on a zero-width match, or, in other words, a boundary condition. In the following snippet I want to split on the boundary between letters and digits so I use zero-width look behind and look-ahead assertions to match a point in the string preceded by a letter and followed by a digit or vice versa.

$ perl -e '
> $str = q{abc123def456ghi};
> @elems =
>    split m
>    {(?x)
>       (?:
>          (?<=[a-z]) # look behind for letter
>          (?=[0-9])  # look ahead for digit
>       )
>       |             # or
>       (?:
>          (?<=[0-9]) # look behind for digit
>          (?=[a-z])  # look ahead for letter
>       )
>    }, $str;
> print qq{$_\n} for @elems;'
abc
123
def
456
ghi
$
[download]

I hope this throws more light on the various ways split can be used.

Cheers,

JohnGG