Re: Using Archive::Tar on tar data already in memory

Use IO::Scalar and pass it a reference to your unbzip2'ed data (tested):

#!/usr/bin/perl -w
use strict;
use Compress::Bzip2;
use Archive::Tar;
use IO::Scalar;
use Data::Dumper;
$Data::Dumper::Indent = 1;

my $file = shift or die "usage: $0 filename.tar.bz2\n";

my $bz = bzopen($file,"r") or die;
my ($out, $buf);
$out .= $buf while $bz->bzread($buf) > 0;

my $fh = IO::Scalar->new(\$out);

my $tar = Archive::Tar->new;
$tar->read($fh) or die "Cannot read from \$fh";
my @fileinfo = $tar->list_files([qw(name size)]);
print Dumper(\@fileinfo);
[download]

--shmem

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}

Comment on Re: Using Archive::Tar on tar data already in memory Download Code

Replies are listed 'Best First'.

Re^2: Using Archive::Tar on tar data already in memory
by alpiner2 (Initiate) on Oct 02, 2007 at 15:47 UTC

Suppose we were to take this one step further and have this completely in memory without reading in a file at all.

I'm using LWP::Simple and pull down a tar.gz from a cgi that prints the binary data.
$tarInput is a scalar which contains the tar data. Since gzread (or bzread) can't read in
scalars or filehandles created from IO::Scalar, need to use a combination of the above 2 posts.
I pass $tarInput to Compress::Zlib::memGunzip and it returns another scalar with the uncompressed
data. Take that data and create a filehandle with the IO::Scalar module and pass that to
$tar->read. I had been working on finding a solution for this and thought this thread would be appropriate
to post my findings. As always there could be more than one way to do this, this just happens to
work for me.

use Archive::Tar;
use LWP::Simple;
use IO::Scalar;
use Compress::Zlib;
use strict;

my $device = shift;

my $tarInput = get "http://somehost/cgi-bin/getTar.cgi?device=$device"
+;

my $uncomptar = Compress::Zlib::memGunzip($tarInput);
my $sh = new IO::Scalar \$uncomptar;
my $tar = Archive::Tar->new;
$tar->read($sh);
print join "\n", $tar->list_files;
[download]

[reply]
[d/l]


Don't ask to ask, just ask
	PerlMonks