You can't do it easily with a single regex, but you can do it with a modest amount of code:

use strict;
use warnings;

while (<DATA>) {
    if (m|<list>| .. m|</list>|) {
        s/^(?!<list>)|(?<=<list>)/<item>/g;
        s-(?=</list>)|(?<!</list>)(?=\n)-</item>-g;
    }
    
    print;
}

__DATA__
The first quick brown fox jumps over the lazy dog.
<list>The quick brown fox jumps over the lazy dog.
The quick brown fox jumps over the lazy dog.
The quick brown fox jumps over the lazy dog.</list>
The last quick brown fox jumps over the lazy dog.
[download]

Prints:

The first quick brown fox jumps over the lazy dog.
<list><item>The quick brown fox jumps over the lazy dog.</item>
<item>The quick brown fox jumps over the lazy dog.</item>
<item>The quick brown fox jumps over the lazy dog.</item></list>
The last quick brown fox jumps over the lazy dog.
[download]

Here is a single regex that seems to do the trick. It does it by using look-around assertions before and after the "The quick ... dog. " phrase we want to modify and by using alternation. Here is the code

use strict;
use warnings;

my $qbf =
   q{The quick brown fox jumps over the lazy dog. };
(my $qbfForRX = $qbf) =~ s{\s}{\\s}g;

my $message
   = $qbf x 7
   . qq{\n<list>}
   . ($qbf. qq{\n}) x 2
   . $qbf
   . qq{</list>\n}
   . $qbf x 6
   . qq{\n};

print $message, qq{\n};

my $rxToChange = qr
   {(?x)                          # Use extended syntax
      (?:                         # Non-capture group
                                  #   for alternation
                                  # Either ...
         (?<=\n)(?=$qbfForRX)     # Move engine to point
                                  #   preceded by newline
                                  #   and followed by
                                  #   phrase
      |                           # ... or ...
         (?<=<list>)(?=$qbfForRX) # Move engine to point
                                  #   preceded by <list>
                                  #   and followed by
                                  #   phrase
      )                           # Close non-capture
                                  #   group
      ($qbfForRX)                 # Capture phrase
      (?=(?:\n|</list>))          # If followed by either
                                  #   newline or </list>
   };

$message =~ s{$rxToChange}{<item>$^N</item>}g;

print $message;
[download]

and when run it produces
Read more... (3 kB)

You were right when you said "You can't do it easily ...". Problems like this would become easier if look-behind assertions were able to accept variable width patterns. I wasted some time trying to work around that before thinking of moving the alternation outside the look-behind. I wasted even more time because I was interpolating the phrase directly into the regex not realising that the 'x' flag was eating the spaces in it. Doh!

Cheers,

JohnGG

Now do it when you don't know what the text is up front and the text varies from line to line.

With this version you might as well just have used a print statement containing the litteral output. I'm sure in OP's real problem the text is not as shown. A better sample may have comprised words like "foo bar baz" and been much shorter, but there were enough lines there that you should probably have been able to read between them. :).

---

DWIM is Perl's answer to Gödel

Then, what you are referring to as paragraphs in your example are lines. This may seem picky, but the distinction between lines and paragraphs makes sense. There is a paragraph mode reading files. See perlrun, there the switch -0 and the special value 00 for it.

blah blah blah     #line \
blah blah blah     #line - paragraph
blah blah blah     #line /
                         <--- paragraph separator
blah blah blah     #line \
blah blah blah     #line - paragraph
blah blah blah     #line /
[download]

I would do this:

#!/usr/bin/perl
$file = shift;
open(I,"<$file");
local $/;
$_ = <I>;
s|<list>(.*?)</list>|"<list>".join("\n",map{"<item>$_</item>"}
    split"\n",$1)."</list>"|ges;
print;
[download]

You can stuff that into a one-liner:

perl -p00 -e 's|<list>(.*?)</list>|"<list>".join("\n",map{"<item>$_</i
+tem>"}split"\n",$1)."</list>"|ges;' textfile
[download]

greets,
--shmem

_($_=" "x(1<<5)."?\n".q·/)Oo.  G°\        /
                              /\_¯/(q    /
----------------------------  \__(m.====·.(_("always off the crowd"))."·
");sub _{s./.($e="'Itrs `mnsgdq Gdbj O`qkdq")=~y/"-y/#-z/;$e.e && print}

my $bla = qq+The quick brown fox jumps over the lazy dog. The quick br
+own fox jumps over the lazy dog. The quick brown fox jumps over the l
+azy dog. The quick brown fox jumps over the lazy dog. The quick brown
+ fox jumps over the lazy dog. The quick brown fox jumps over the lazy
+ dog.
<list>The quick brown fox jumps over the lazy dog.
The quick brown fox jumps over the lazy dog.
The quick brown fox jumps over the lazy dog.</list>
The quick brown fox jumps over the lazy dog. The quick brown fox jumps
+ over the lazy dog. The quick brown fox jumps over the lazy dog. The 
+quick brown fox jumps over the lazy dog. The quick brown fox jumps ov
+er the lazy dog. The quick brown fox jumps over the lazy dog.+;

$bla =~ s~(<list>)(.*?)(</list>)~$1.subst($2).$3~es;
print $bla;

sub subst{
  my ($string) = @_;
  print $string;
  my $res = "";
  for(split(/\n/,$string)){
    $res .= '<item>'.$_.'</item>'."\n";
  }
  return $res;
}
[download]

my $inlist = 0;
while(<>) {
    chop;
    if ( $inlist ||= /^(\<list\>)(.*)$/ ) {
        print "$1<item>";
        $_=$2;
    }
    $inlist &&= !( /^(.*)(\</list\>)$/
                   and print "$1</item>"
                   and $_=$2 );
    print "$_\n";
}
[download]