Sure ... just add the data into a hash of arrays where the key is the stuff before the = and the value is an array of the stuff afterwards:

#!/usr/bin/perl

use strict;
use warnings;

my %hash;
while( <DATA> ) {
  chomp;
  next unless $_;
  my( $key, $val ) = split( /\s+=\s+/, $_ );
  push( @{$hash{$key}}, $val );
}

foreach my $key ( sort keys %hash ) {
  print $key, " = " . join( ',', @{$hash{$key}} ), "\n";
}


__DATA__
A = 1
A = 2
A = 3

B = 5
B = 1
B = 7

C = 4
[download]

while (<DATA>)
{
  my ($key, $val) = split / = /;
  push @{$data{$key}}, $val;
}
[download]

So track the order too.

if ( not exists $order{$key} ) {
    $order{$key} = 0 + scalar keys %order;
}
[download]

⠤⠤ ⠙⠊⠕⠞⠁⠇⠑⠧⠊

Or use Tie::IxHash on the data hash, before you start filling it.

use Tie::IxHash;
tie %data, 'Tie::IxHash';
[download]

Tie::IxHash actually does pretty much the same thing as your code, under the hood.

Something like this perhaps:

use strict;
use warnings;

my %data;

while (<DATA>) {
  next unless /\S/;
  chomp;

  my ($k, $v) = split / = /;
  push @{$data{$k}}, $v;
}

foreach (sort keys %data) {
  print "$_ = ", join(',', @{$data{$_}}), "\n";
}

__DATA__
A = 1
A = 2
A = 3

B = 5
B = 1
B = 7
[download]

A better way is to create a hash containing your arrays as values (I put your input into a file named 'test'):

use Data::Dumper;
my %h;

open FH, "test";
while (<FH>)
{
   chomp;
   next if /^\s*$/;
   split /=/;
   push @{$h{$_[0]}}, $_[1];
}
close FH;

print Dumper \%h;
[download]

$VAR1 = {
          'A ' => [
                    ' 1',
                    ' 2',
                    ' 3'
                  ],
          'B ' => [
                    ' 5',
                    ' 1',
                    ' 7'
                  ]
        };
[download]

Enjoy,
Mickey

Presuming you want to preserve the order and you won't have different interleaved (e.g. A A A B B B C C A B B, where keys seen before reoccur later) you just need to store off the current key's value.

my( $lastkey, @row );
while( <DATA> ) {
  chomp;

  next if /^\s*$/;

  my( $key, $datum ) = split /\s+=\s+/;
  if( $key ne $lastkey ) {
    print "$lastkey = ", join( ",", @row ), "\n" if @row;
    @row = ();
    $lastkey = $key;
  }
  push @row, $datum;
}

print "$lastkey = ", join( ",", @row ), "\n" if @row;
__END__
A = 1
A = 2
A = 3

B = 5
B = 1
B = 7

C = 8
C = 6
C = 7
C = 5
C = 3
C = 0
C = 9
[download]

$_ = "A = 1
A = 2
A = 3

B = 5
B = 1
B = 7
";


1 while s/((\w+) = .+)
\2 = (.+)/$1, $3/;
[download]

my %hash;
while(<>) {
    chop;
    my ( $k, $v ) = split /\s*\=\s*/;
    $hash{ $k } = defined ( $hash{ $k } )
        ? $hash{$k } . ",$v"
        : $v;
}
while ( my ($k, $v ) = each %hash ) {
    print "$k = $v\n";
}
[download]