Module RFC: Audio::Scrobbler::SimilarArtists

This module retrieves "Similar Artists" information from audioscrobbler.net and caches it for a specified amount of time, to speed up things and prevent hammering the source server.

I'd like to know if the code could be optimized (of course, we're using Perl, damnit!) and whether the chosen namespace would be ok for this module.

package Audio::Scrobbler::SimilarArtists;
use strict;
use Cache::File;
use Carp;
use File::Path qw/mkpath/;
use LWP::Simple;
use URI::Escape;
use XML::Simple;

our $VERSION = '0.01';

sub new {
   my ($class, %parameters) = @_;

   my $self = bless ({}, ref ($class) || $class);
   my %options = (
      min_match  => 75,
      cache_time => '1 week',
      cache_dir  => '/tmp/audioscrobbler.cache',
      %parameters,
   );

   $self->{'_options'} = \%options;

   # Check if the cache_dir exists
   if(!-d $self->{'_options'}->{'cache_dir'}) {
      eval { mkpath($self->{'_options'}->{'cache_dir'}) };
      if($@) {
         Carp::croak("Couldn't create $self->{'_options'}->{'cache_dir
+'}:$@");
      }
   }

   return $self;
}

sub lookup {
   my ($self, $name) = @_;

   unless($name) {
      Carp::croak('No name supplied!');
      return;
   }

   my $cache = new Cache::File (
      cache_root => $self->{'_options'}->{'cache_dir'},
   );

   my $filename = $name;
      $filename =~ s/\W//g;
   my @info;
   @info = @{$cache->thaw($filename)}
      if(ref $cache->thaw($filename) eq 'ARRAY');

   unless(@info) {
      my $data = get(sprintf("%s/%s/%s",
                     'http://ws.audioscrobbler.com/1.0/artist',
                      uri_escape($name),
                     'similar.xml')
                 );
      if($data) {
         my $xs   = new XML::Simple();
         my $x    = $xs->XMLin($data);

         if(ref $x->{'artist'} eq 'ARRAY') {
            foreach my $item (@{$x->{'artist'}}) {
               next unless ref $item eq 'HASH';
               push @info, $item
                  if($item->{'match'} >= $self->{'_options'}->{'min_ma
+tch'});
            }
            $cache->freeze($filename, \@info,
                           $self->{'_options'}->{'cache_time'});
         }
      } else {
         Carp::carp("Couldn't fetch XML for $name");
         return ();
      }
   }
   return @info;
}
[download]

I've taken out the POD, for this post is long enough already ;-)

Update: but I do think the SYNOPSIS is the least I can show:

=head1 SYNOPSIS

  use strict;
  use Audio::Scrobbler::SimilarArtists;

  my $sa = Audio::Scrobbler::SimilarArtists->new( 
              minmatch => 85,
              cache_time => '1 week',
              cache_dir  => '/var/cache/audioscrobbler'
           );
  my @artists = $sa->lookup('Hate Forest');

  if(@artists) {
     print "<a href=\"$_->{'url'}\">$_->{'name'}</a> ".
           "(match: $_->{'match'})\n"
        foreach(@artists);
  }
[download]

Update2: maybe WebService::LastFM::SimilarArtists is a better name, since Audio:: might imply it actually does something with audio?

--
b10m

All code is usually tested, but rarely trusted.

Comment on Module RFC: Audio::Scrobbler::SimilarArtists Select or Download Code

Replies are listed 'Best First'.

Re: Module RFC: Audio::Scrobbler::SimilarArtists
by radiantmatrix (Parson) on Feb 07, 2006 at 18:52 UTC

You're doing too much work, when you can just use Memoize and take advantage of the Memoize::Storable capability.

package Audio::Scrobbler::SimilarArtists;
use strict;
use Memoize;

my %cache;

sub new {
   my ($class, %parameters) = @_;

   my $self = bless ({}, ref ($class) || $class);
   my %options = (
      min_match  => 75,
      cache_time => '1 week',
      cache_file  => '/tmp/audioscrobbler.cache',
      %parameters,
   );

   $self->{'_options'} = \%options;
   $self->{cache}      = \%cache;

   tie %{ $self->{cache} } => 
     'GDBM_File', $self->{_options}->{cache_file}, O_RDWR|O_CREAT, 066
+6;
   memoize 'lookup', SCALAR_CACHE => [HASH => \%cache];
   
   return $self;
}

sub lookup {
   # same as above, but without caching code: memoize handles that.
}
[download]

<-radiant.matrix->
A collection of thoughts and links from the minds of geeks
The Code that can be seen is not the true Code
I haven't found a problem yet that can't be solved by a well-placed trebuchet

[reply]
[d/l]


go ahead... be a heretic
	PerlMonks