#!/usr/bin/perl

use strict;
use warnings;

use Term::ANSIColor;

# Color modifiers
my @mods = ('', 'bold',  'dark',    'underline',
                'blink', 'reverse', 'concealed');

# Foreground colors
my @fgs  = ('black', 'red',     'blue', 'yellow',
            'green', 'magenta', 'cyan', 'white');

# Background colors
my @bgs  = ('', 'on_black', 'on_red',     'on_blue', 'on_yellow',
                'on_green', 'on_magenta', 'on_cyan', 'on_white');

MAIN:
{
    print "\n             \\ on_       black  red  blue yellow green magenta cyan white\n";

    # Modifiers only
    foreach my $mod (@mods) {
        colored_line($mod, '');
    }

    # Foreground colors combined with modifiers
    foreach my $mod (@mods) {
        foreach my $fg (@fgs) {
            colored_line($mod, $fg);
        }
    }
}

exit(0);

### Subroutines ###

sub colored_line
{
    my ($mod, $fg) = @_;

    # Line label
    printf(" %9s %-7s ", $mod, $fg);

    # Segments with background colors
    for my $bg (@bgs) {
        print(colored([$mod, $fg, $bg], ' Text '));
    }

    print("\n");
}

# EOF