use strict;

nested_for(
  sub {print "@_\n";},
  [1..2], ['a'..'c'], ['A'..'D']
);

sub nested_for {
  ret_iter(@_)->();
}

sub ret_iter {
  my $fn = shift;
  my $range = shift;
  my $sub = sub {$fn->($_, @_) for @$range};
  return @_ ? ret_iter($sub, @_) : $sub;
}
[download]

Oh Wow!

I bow to tilly!

I am going to REALLY study this: it works! correctly! it's one-third the size! it looks tricky but not f**** insane! and NO POINTER ARITHMETIC!!!!

This is the sort of answer that shows that i'm a tyro at perl AND why! I'm obviously still stuck in some sort of tunnel vision caused by programming in c/c++.

To me this is a great Zen Koan to meditate on!

Thanks tilly, and everyone who responded to this query!

---madams :) x $POSIX::LDBL_MAX

That was beautiful. I'm writing primarily so more people can see it. I also did a little rewrite that isn't an improvement, per se, but is AWTDI and may help people understand what's going on. (Iterating instead of recursing.)

sub ret_iter {
  my $sub = shift;
  while (my $range = pop) {
    my $inner = $sub;
    $sub = sub { $inner->(@_, $_) for @$range };
  }
  return $sub;
}
[download]

I made it so it changes elements on the right fastest, like a counter.

---

Caution: Contents may have been coded under pressure.

First of all I strongly suggest using strict up at the top, it will catch even more errors for you. Of course you need to use vars as well.

After that fixing it to work is just a matter of walking through and fixing complaints. You have an extra ')' before a ||. One-line for loops need to either change the format or need the braces. There are a few undeclared variables. A few more cases where // is used instead of # for a comment. A few $ missing. (ie You want --$level rather than --level.) Your final return statement should not be there.

All of this is pretty mechanical, but I am loathe to post the final result since the resulting code is very ugly. A native Perl version of this would be easy to write and would look much nicer. Perhaps if I get some time...

Hey thanx for the critique ...

Added "use strict" , switched to a perl aware editor (boy that caught alot just switching editors)(changed @curlevel to $curlevel..the GOOD editor caught that)

split up the stmt that had the "||" in it (that somehow fixed that), fixed the munged comments, and that oneline for loop. Now no syntax errors (yeah!)

Mostly i am looking for someone to tell me if i got the pointer arithmetic related crap ported right .. when i use the module i'm getting some nonsense output (examples are uploaded to here).

One thing why get rid of the "return 1;" at the end? every example of writing a module says it should return "1" to signal proper loading.

The reason for removing the return statement is that you are not supposed to use that outside of functions (eval, do).

Just end with:

1;
[download]

and it will work.

As for the pointer logic, sorry. No energy to go through it. It looked like a mess FWIW. I would just use recursion for this problem. (OK, so you take a performance hit.)

    #oops...pointer arithmetic..
    #curlevel = curvals + level;
    $curlevel = $level;

    # shouldn't this be more like:
    $curlevel = @$curvals + $level;
    # or some such?  i'm not entirely certain as to why curvals got dr
+opped here...
[download]

NOTE: there is no error checking for incoming variables in this version.

#!/usr/bin/perl -w
package forFun;
use strict;

use Exporter;
@ISA = qw(Exporter);
@EXPORT = qw(&ForFun);


sub ForFun {
   my ($startval, $endval, $workfunc) = @_;
   my ($level, $curvals) = (0, []);

   push @$curvals, $_ foreach (@$startval);

   while ($level > -1) {
      $level = @$startval - 1;

      while ($curvals->[$level] <= $endval->[$level]) {
         &$workfunc($curvals);
         ($curvals->[$level])++;
      }

      $level--;
      while (++($startval->[$level]) > $endval->[$level]);
         last if (--$level < 0);
      }
   }

   return;
}


1;
[download]

Hope this helps,

jynx

ps the code above is untested but should be able to work pretty much as is...