my $str      = 'Fsih my test variable is fsihd or is it gfsih or gfsih
+d fsih';
#                                        1111            2222     3333
+  4444
my $substr   = 'fsih';
my $replace  = 'fish';
my $instance = 3;  # 3rd

print("$str\n");

my $pos = -length($substr);

for (;;) {
   last if !$instance--;
   $pos = index($str, $substr, $pos + length($substr));
   last if $pos < 0;
}

substr($str, $pos, length($substr), $replace)
   if $pos >= 0;

print("$str\n");
[download]

Update: Fixed off-by-one error.

A tad simpler looping, and case-insensitive:

my $foo   = 'Fsih my test variable is fsihd or is it gfsih or gfsihd f
+sih';
my $from  = 'fsih';
my $which = 3;
my $to    = 'FISH'; # makes it easy to see

$foo =~ /\Q$from\E/ig for (1..$which);
substr($foo, pos($foo) - length($from), length($from), $to) if pos($fo
+o);
print "Foo = $foo\n";
[download]

---

Caution: Contents may have been coded under pressure.

That reminds me of /c!

my $str      = 'Fsih my test variable is fsihd or is it gfsih or gfsih
+d fsih';
#                                        1111            2222     3333
+  4444
my $substr   = 'fsih';
my $regexp   = qr/\Q$substr\E/;
my $replace  = 'fish';
my $instance = 3;  # 3rd

print("$str\n");

scalar $str =~ /\G.*?$regexp/gc
   while --$instance;

$str =~ s/\G(.*?)$regexp/$1$replace/;

print("$str\n");
[download]

The /c is needed in case there are less than $instance instances of the search string.

Now, is there a way to do it with Regular Expression?

my $str      = 'Fsih my test variable is fsihd or is it gfsih or gfsih
+d fsih';
#                                        1111            2222     3333
+  4444
my $substr   = 'fsih';
my $regexp   = qr/\Q$substr\E/;
my $replace  = 'fish';
my $instance = 3;  # 3rd

print("$str\n");

my $pre_count = $instance - 1;
$str =~ s/((?:$regexp.*?){$pre_count})$regexp/$1$replace/;

print("$str\n");
[download]

You might have noticed both of these are case sensitive. Both can be made case-insensitive. The non-regexp version is most likely much faster. The regexp version can handle regexps instead of constant strings.

my $foo = 'Fsih my test variable is fsihd or is it gfsih or gfsihd fsi
+h';
# Replace the 3rd
$foo =~ s/((?:fsih.*?){2})fsih/$1fish/i or warn "Not found";
print "Foo = $foo\n";
[download]

or to pass the index in use:

use warnings;
use strict;

my $foo = 'Fsih my test variable is fsihd or is it gfsih or gfsihd fsi
+h';
my $i = 2; # Replace the 3rd
$foo =~ s/((?:fsih.*?){$i})fsih/$1fish/i or warn "Not found";
print "Foo = $foo\n";
[download]

---

Perl is Huffman encoded by design.

my $i= 0;
$str =~ s/(...)/ 3 == ++$i ? 'fish' : $1 /ge;
[download]

my $i = 3;
0 while $str =~ /fsih/gi && --$i;
substr( $str, $-[0], $+[0]-$-[0], 'fish' )   if  ! $i;
[download]

my $instance = 3;
$string = s/fsih/--$instance?$&:'fish'/eg;
[download]