%hash = ($temp => $temp);

#!/usr/bin/perl -w
use strict;
use Data::Dumper;

my @array = ("white","blue","yellow");
my %hash = ();
foreach my $temp (@array) {
     $hash{$temp} = $temp;
}

print Dumper \%hash;
print join (" ",keys %hash);
[download]

$VAR1 = {
          'white' => 'white',
          'blue' => 'blue',
          'yellow' => 'yellow'
        };
white blue yellow
[download]

I assume this is just contrived code to ask a question, but, just in case, a hash slice makes the 'foreach' block unnecessary.

my @array = ( 'white', 'blue', 'yellow' );
my %hash;
@hash{ @array } = @array;
[download]

Or, without the array:

my %hash;
@hash{ 'white', 'blue', 'yellow' } = ( 'white', 'blue', 'yellow' );
[download]

I had an issue in my code,that's why i had asked this question and given a small example which was very close to the issue i was facing.And your reply helped me to solve the issue. i feel instead of @hash{ @array } = @array; $hash{@array} = @array ; would be better

Have you tried it like that?

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper 'Dumper';

my @colors = qw( white yellow green );
my %hash;
$hash{ @colors } = @colors;

print Dumper \%hash;

__END__
[download]

I get this in perl 5.8.6:

$VAR1 = {
          '3' => 3
        };
[download]

Perl assumes you want to evaluate the array in scalar context. Better to stick to the same notation everyone else uses for hash slices.

HTH,
Charles

Hi, try this here is the problem and solution,

The problem is your key and value is assigned to hash. Each time they assigned. so, in that final value only stored in hash and the key printed for that hash is yellow. ie. That is the problem.

So, don't assigned to hash each time, please use like below mentioned code.

my @array = ("white","blue","yellow");
my %hash = ();
foreach my $temp (@array) {
$hash{$temp}=$temp;
}
print keys %hash;
[download]