Re: Is there a module which Perl has to load when using any module?

in reply to Is there a module which Perl has to load when using any module?

This is a question prompted by What modules are we actually using?. I was wondering if there is some core Perl module which has to be loaded, when it loads another module thru use or require? My idea would be to temporarily modify that module, to print to a log file.

What does that "it" refer to? Perl? If so, then I don't think so. Otherwise, unless I'm severely mistaken, I don't think so either.

However if all you want is to {know,log} which modules get loaded, then you can easily spot the possibility to put code into @INC to do so. E.g.:

#!/usr/bin/perl -l

use strict;
use warnings;

END {
    my @stuff;
    sub record {
        push @stuff, $_[1];
        undef;
    }
    print for @stuff;
}

use lib \&record;
use File::Find;
no lib \&record;

# Do something else, I suppose!

__END__
[download]

For the record this had come up in clpmisc and this kind of solution was suggested by Anno Siegel, who is a precious contributor there. As time permits I'll try to locate the original post.

Comment on Re: Is there a module which Perl has to load when using any module? Select or Download Code

Replies are listed 'Best First'.
Re^2: Is there a module which Perl has to load when using any module? by merlyn (Sage) on Apr 28, 2005 at 15:53 UTC
Actually, it's much simpler than that: `END { print STDERR "Modules used:\n", map { " $_\n" } values %INC; }` [download] -- Randal L. Schwartz, Perl hacker Be sure to read my standard disclaimer if this is a reply.	[reply] [d/l]
Re^3: Is there a module which Perl has to load when using any module? by blazar (Canon) on Apr 28, 2005 at 16:09 UTC
Indeed. Of course the original discussion was about how to monitor module loading on a "per use statement basis", as can be suggested by the minimal example supplied - still sloppily speaking here, but I guess it's easy to understand what I really mean here. But then again it was just an example of how to use a coderef in `@INC` to achieve something similar to what the OP wanted...	[reply] [d/l]
Re^3: Is there a module which Perl has to load when using any module? by DaWolf (Curate) on Apr 28, 2005 at 21:08 UTC
Hi, Merlin. I'm curious... Why printing to STDERR instead of STDOUT? Regards, Er Galvão Abbott www.galvao.eti.br Porto Alegre Perl Mongers	[reply]
Re^4: Is there a module which Perl has to load when using any module? by merlyn (Sage) on Apr 29, 2005 at 00:03 UTC
For the same reason anything gets printed to STDERR: to make sure it's not lost down the pipeline. -- Randal L. Schwartz, Perl hacker Be sure to read my standard disclaimer if this is a reply.	[reply]
Re^3: Is there a module which Perl has to load when using any module? by djp (Hermit) on Apr 29, 2005 at 01:09 UTC
Brilliant. Can I suggest sorting for readability: `END { print STDERR "Modules used:\n", map { " $_\n" } sort values %INC; }` [download]	[reply] [d/l]

In Section Seekers of Perl Wisdom