The problem is that Perl doesn't abstract the concept of appending for its various containers (scalars, arrays, and hashes), because Perl isn't inherently OO. I don't know if Perl 6 is going this route, where you could say:

$foo.append($bar);
@foo.append(@bar);
%foo.append(%bar);
[download]

And in the same vein, perhaps:

$foo.prepend($bar);
@foo.prepend(@bar);
%foo.prepend(%bar);
[download]

In recent Perls, we can write this as:

# append($x, $y) appends $y to $x
# etc.
# prepend() left as a simple exercise to the reader

sub append (\[$@%]\[$@%]) {
  use Scalar::Util 'reftype';
  use Carp qw( croak );

  my ($l, $lt, $r, $rt) = map { $_, reftype($_) } @_;

  if ($lt eq $rt) {
    if ($lt eq 'SCALAR') {
      $$l .= $$r;
    }
    elsif ($lt eq 'ARRAY') {
      push @$l, @$r;
    }
    elsif ($lt eq 'HASH') {
      @$l{keys %$r} = values %$r;
    }
    else {
      croak "append($lt,$rt) not implemented";
    }
  }
  else {
    croak "append($lt,$rt) not implemented";
  }
}
[download]

I'd expect friction coming from the "what does append/prepend mean for hashes?" faction, but I'd say it's a matter of precedence. Appending to a hash, when there are duplicate keys, uses the new values, and prepending would use the old values.