#!/usr/bin/perl -l
use warnings;
use strict;
use List::Util qw( reduce );
sub combinations {
no warnings qw( once );
reduce { outer_r($a,$b) } [[]], reverse @_;
}
sub outer_r {
my ($ys, $xs) = @_;
my @product;
foreach my $x (@$xs) {
foreach my $y (@$ys) {
push @product, [$x, @$y];
}
}
return \@product;
}
####
use Data::Dumper;
$Data::Dumper::Terse = 1;
$Data::Dumper::Indent = 0;
print Dumper( combinations( [1..3], ["a","b"] ) ), "\n";
# [[1,'a'],[1,'b'],[2,'a'],[2,'b'],[3,'a'],[3,'b']]
##
##
sub charset_combinations {
my @charsets = map [split//], @_;
map join("", @$_), @{ combinations( @charsets ) };
}
##
##
my @abcees3 = charset_combinations( ("abc") x 3 );
print "@abcees3\n";
# aaa aab aac aba abb abc aca acb acc\
# baa bab bac bba bbb bbc bca bcb bcc\
# caa cab cac cba cbb cbc cca ccb ccc
##
##
my @charsets = qw( abc 123 !@$ );
foreach my $string_length (0 .. @charsets) {
my @genstrings =
charset_combinations( @charsets[0..$string_length-1] );
print "$string_length: @genstrings\n";
}
# 0:
# 1: a b c
# 2: a1 a2 a3 b1 b2 b3 c1 c2 c3
# 3: a1! a1@ a1$ a2! a2@ a2$ a3! a3@ a3$\
# b1! b1@ b1$ b2! b2@ b2$ b3! b3@ b3$\
# c1! c1@ c1$ c2! c2@ c2$ c3! c3@ c3$