note
Limbic~Region
[tye],
<br />
I expanded [393064|the code] I came up with for combinations of a fixed size:
<CODE>
#!/usr/bin/perl
use strict;
use warnings;
my $iter = combo( 30..50 );
while ( my @combo = $iter->() ) {
print "@combo\n";
}
sub combo {
my @list = @_;
return sub { () } if ! @_;
my (@position, @stop, $end_pos, $done);
my ($by, $next) = (0, 1);
return sub {
return () if $done;
if ( $next ) {
$by++;
return () if $by > @list;
@position = (0 .. $by - 2, $by - 2);
@stop = @list - $by .. $#list;
$end_pos = $#position;
$next = undef;
}
my $cur = $end_pos;
{
if ( ++$position[ $cur ] > $stop[ $cur ] ) {
$position[ --$cur ]++;
redo if $position[ $cur ] > $stop[ $cur ];
my $new_pos = $position[ $cur ];
@position[ $cur .. $end_pos ] = $new_pos .. $new_pos + $by;
}
}
if ( $position[0] == $stop[0] ) {
$position[0] == @list ? $done = 1 : $next = 1;
}
return @list[ @position ];
}
}
</CODE>
I haven't analyzed its O factor or spent a lot of time with good benchmarks, but it does appear to be considerably faster for combinations of 30..50.
<div class="pmsig"><div class="pmsig-180961">
<p>
Cheers - [Limbic~Region|L~R]
</p>
</div></div>
128286
128293