=> is exactly like the list seperator ,, but you can put barewords on the left hand side.

@a = ('a',   4);  # ok
@a = ('a' => 4);  # ok
@a = (a   => 4);  # ok
@a = (a,     4);  # XXX ERROR
print("Hello" => " " => "World" => "\n");  # Why not.

# Often used for hashes:
%h = ( key => 'value' );
[download]

-> dereferences a reference:

@a = qw( a b c );
$ap = \@a;
print($ap->[2]);  # prints: c

%h = ( key => 'value' );
$hp = \%h;
print($hp->{key});  # prints: value

$obj = MyClass->new();
$obj->method();
[download]

To interpolate something (as relevant here) is to substitute it with its value:

$a = 'test';
print('$a\n');   # prints: $a\n
print("$a\n");   # prints: test and a newline
print("\$a\n");  # prints: $a and a newline

@a = qw( a b c );
print('@a\n');   # prints: @a\n
print("@a\n");   # prints: abc and a newline
print("\@a\n");  # prints: @a and a newline
[download]

You should take your time and work through the perlsyn and perlop manpages (or perldocs). That will give you a solid foundation as you learn perl. merlyn's Llama book would be a gentler alternative.

"Interpolated" means that the values of variables are substituted where the variables occur. That happens for scalars and arrays - items with the $ and @ sigils.

First I'll answer the quoting question. Try the following snippet.

my $text = "Hello world\n";
my $var  = 'Hello world\n';

print $text;
print $var;
[download]

In the case of $text, we used " (double quotes) and thus, \n was expanded to mean a newline. In the case of $var, we used single quotes, and \n remained the literal characters \ and n.

Now try this code:

my $text = "Hello world\n";
print "$text";
print '$text';
[download]

In the case of the first print statement, the variable $text is interpolated within the string (its value is put into the string). In the case of the second print statement, $text is the literal text printed.

Now for =>. => is sometimes called the "fat comma". It's most common use is in declaring elements of a hash, as in:

my %hash = ( This => 10,
             That => 20
            );
[download]

The fat comma also has the effect of 'single quoting' the text immediately to its left. So the above snippet is equal to:

my %hash = ( 'This' , 10,
             'That' , 20
           );
[download]

Now for ->. That is used for dereferencing, which is an entirely different subject, having nothing to do with the => fat comma. If $aref is a reference to an array, one of the notations you can use to dereference that ref, and grab a single element is to use the dereference operator ->, like this: $aref->[3]. That's the same as:  ${$aref}[3], and a lot less ambiguous than something like $$aref[3].

As Zaxo has stated, you should have a look at perlsyn, perlop, and perlreftut.