Re^2: split every other value

You got your odd/even mixed up. The first element is at index 0, which is even. Also, enter splice and statement modifiers.

while( @array ) {
    my ( $even, $odd ) = splice @array, 0, 2;
    push @odd, $odd if defined $odd;
    push @even, $even if defined $even;
}
[download]

It is worth noting that this would be buggy if the list could possibly have undefs in it (not the case here; but I'd put a comment to that effect in the code).

Obscure trickery for the fun of reducing it further, but don't do this at home:

( $even[ @even ], $odd[ @odd ] ) = splice @array, 0, 2 while @array;
[download]

Makeshifts last the longest.

Comment on Re^2: split every other value Select or Download Code

Replies are listed 'Best First'.
Re^3: split every other value by beable (Friar) on Aug 07, 2004 at 01:25 UTC
I shouldn't have used the names "@odd" and "@even", seeing as how we're supposed to be dealing with text. So here's a program which doesn't use those terribly misleading names, and deals with undefs. `#!/usr/bin/perl use strict; use warnings; my @array = map{chr} ('32' .. '126'); push @array, undef, undef; unshift @array, undef, undef, undef; # split elements into two arrays my (@arr0, @arr1); while (@array > 1) { my ($el0, $el1) = splice @array, 0, 2; push @arr0, $el0; push @arr1, $el1; } # get the last element if there is one if(@array) { push @arr0, shift @array; } # check that all elements were gotten die "still elements left" if (@array); print "arr0 = @arr0\narr1 = @arr1\n"; __END__` [download]	[reply] [d/l]
Re^4: split every other value by Aristotle (Chancellor) on Aug 07, 2004 at 01:34 UTC
If you do away with the conditionals like that, the temporaries in the while loop are superfluous. `my ( @arr0, @arr1 ); while( @array > 1 ) { push @arr0, shift @array; push @arr1, shift @array; } push @arr0, shift @array if @array;` [download] Or you could pull the conditional back into the loop: `my ( @arr0, @arr1 ); while( @array ) { push @arr0, shift @array; push @arr1, shift @array if @array; }` [download] Makeshifts last the longest.	[reply] [d/l] [select]
Re^5: split every other value by beable (Friar) on Aug 07, 2004 at 01:52 UTC
Yep looks good to me.	[reply]


Clear questions and runnable code get the best and fastest answer
	PerlMonks