Re^3: Specializing Functions with Currying

 'boldital' => do {
    my $i = curry \&wrap_with_html => ( 'i' );
    my $b = curry \&wrap_with_html => ( 'b' );
    sub { $b->( $i->( @_ ) ) }
},
[download]

Neat use of =>. As for composition, as an inveterate Haskell hacker (well, hacker-wannabe), I'd prefer to have that as a primitive, too:

sub compose
{
   my ($f, $g) = @_;

   return sub { $f->($g->(@_)); }
}

# ...

'boldital' => &compose(&curry(\&wrap_with_html, 'i'),
                       &curry(\&wrap_with_html, 'b')),
[download]

The idea of functions that operate on functions and return other functions is much more useful than it first seemed to me. If you never think about functions as first-class objects, having a compose function seems incredibly redundant. Once you start building functions on-the-fly, composition becomes indispensible.

I guess I should write part 2 of my Perlesque Intro to Haskell, then.

-- F o x t r o t U n i f o r m Found a typo in this node? /msg me % man 3 strfry

Comment on Re^3: Specializing Functions with Currying Select or Download Code

Replies are listed 'Best First'.
Re^4: Specializing Functions with Currying by stvn (Monsignor) on Aug 06, 2004 at 13:46 UTC
Why limit `compose` to just two functions? `sub compose { my ($f, $f2, @rest) = @_; return $f unless defined $f2; return &compose(sub { $f2->($f->(@_)) }, @rest); } *bold_italic_and_underlined_paragraph = compose( &curry(\&wrap_with_html, 'u'), &curry(\&wrap_with_html, 'b'), &curry(\&wrap_with_html, 'i'), &curry(\&wrap_with_html, 'p') ); print bold_italic_and_underlined_paragraph("test");` [download] -stvn	[reply] [d/l] [select]
Re^5: Specializing Functions with Currying by Aristotle (Chancellor) on Aug 06, 2004 at 22:55 UTC
Of course, that's just asking for it. `my $biup = compose map curry( \&wrap_with_html, $_ ), qw( p u i b );` [download] Now that actually looks like a construct you're likely to see in some flavour of functional programming language. Makeshifts last the longest.	[reply] [d/l]
Re^5: Specializing Functions with Currying by jryan (Vicar) on Aug 06, 2004 at 21:03 UTC
Why recurse when you can iterate instead? :) `use List::Util qw(reduce); sub compose { reduce { sub { $b->($a->(@_)) } } @_; }` [download] Of course, that doesn't actually work because Perl's reduce uses global variables ($a,$b). But, we can roll our own: `sub compose { my $c = shift; foreach my $s (@_) { my $o = $c; $c = sub { $s->($o->(@_)) } } $c }` [download]	[reply] [d/l] [select]
Re^6: Specializing Functions with Currying by stvn (Monsignor) on Aug 06, 2004 at 21:56 UTC
Why recurse when you can iterate instead? :) gasp .... thats not very functional! (I wont even bring up the fact you are using variable assignment, tssk tssk) If we really want to be "efficient" about it, we would avoid the overhead of the wrapper subroutine, and just use straight perl's closures. `sub compose { my (@funcs) = @_; return sub { my (@args) = @_; foreach my $func (@funcs) { @args = $func->(@args); } return @args; }; }` [download] But really, that takes all the fun out of it ;-) -stvn	[reply] [d/l]
Re^7: Specializing Functions with Currying by jryan (Vicar) on Aug 06, 2004 at 22:21 UTC
Re^8: Specializing Functions with Currying by tilly (Archbishop) on Aug 06, 2004 at 22:29 UTC
Some notes below your chosen depth have not been shown here
Re^8: Specializing Functions with Currying by stvn (Monsignor) on Aug 06, 2004 at 23:04 UTC
Some notes below your chosen depth have not been shown here
Re^7: Specializing Functions with Currying by ihb (Deacon) on Aug 08, 2004 at 00:19 UTC
Re^4: Specializing Functions with Currying by Aristotle (Chancellor) on Aug 06, 2004 at 04:38 UTC
I had seen that some primitive exists for this kind of thing in functional programming, but I have never gotten past a brief foray into that world. My first contact with a number of functional concepts was through Perl, and ever since I've meant to learn a serious functional language. It hasn't happened yet… For anyone looking for an introduction to functional concepts in Perl, Mark-Jason Dominus' Higher Order Perl book is well worth a look… or will be once it's finished. Makeshifts last the longest.	[reply]


Your skill will accomplish what the force of many cannot
	PerlMonks