[jps@secanaws jps]$ perl ipc-write.pl
Can't call method "pack" on an undefined value at /usr/lib/perl5/5.6.1
+/i386-linux/IPC/Msg.pm line 78.
[download]

#!/usr/bin/perl

use IPC::SysV 
  qw(IPC_PRIVATE IPC_CREAT IPC_NOWAIT);
use IPC::Msg;
use Data::Dumper;

use strict;
use warnings;

my $msgtype = 1;
my $message = "hello nr ";
my $messages = 2000;
my $buf;

my $msg = new IPC::Msg('24h', IPC_CREAT);

$msg->set('qbytes' => 32768);

for (my $i = 0; $i < $messages; $i++) {
  my $rv = $msg->snd($msgtype, 
                     pack("L a*",$msgtype,$message . $i),
                     IPC_NOWAIT);
  print "rv of $i is $rv\n"
}

while ($msg->rcv($buf,256, $msgtype, IPC_NOWAIT)) {
  print "$buf\n";
}
[download]

Looking at the code near the line on which the error was reported, we find this set method in 5.6.1:

# IPC/Msg.pm lines 61-79
sub set {
    my $self = shift;
    my $ds;

    if(@_ == 1) {
        $ds = shift;
    }
    else {
        croak 'Bad arg count' if @_ % 2;
        my %arg = @_;
        my $ds = $self->stat
                or return undef;
        my($key,$val);
        $ds->$key($val)
            while(($key,$val) = each %arg);
    }

    msgctl($$self,IPC_SET,$ds->pack);
}
[download]

There is a bug in this code: on line 11 (which is line 71 of the original file), my $ds creates a new $ds variable which goes out of scope at the end of the else block. That is why the final line has an undefined value for $ds when it tries to invoke $ds->pack.

Removing the redundant "my" will fix that problem by ensuring that (as intended) the outer $ds variable is the one used, and indeed in later perls you'll find that exactly this change has been made: replacing

  my $ds = $self->stat
[download]

with

  $ds = $self->stat
[download]

at line 71.

If you don't have permission to make this fix to the code directly, and you can't convince the system administrator to apply the fix for you, there are a couple of ways you can get around it. One way is subclassing to replace the buggy routine:

  {
    package IPC::Msg::Bugfix;
    our @ISA = qw/ IPC::Msg /;
    sub set {
      # corrected version of set here ...
    }
  }
  # in your code
  my $msg = new IPC::Msg::Bugfix('24h', IPC_CREAT);
  # and continue as before
[download]

An alternative is to recode to avoid the path with the bug in it:

  # avoiding buggy multiple-arg set()
  # $msg->set('qbytes' => 32768); 
  my $ds = $msg->stat or die "stat: $!";
  $ds->qbytes(32768);
  $msg->set($ds);
[download]

(Please note, I haven't tested any of this code.)

Hugo

Thanks, Hugo!!

On a side-note, I also needed to do this:

echo "65536" > /proc/sys/kernel/msgmnb
[download]

Thanks to all you helpful monks!!

Hmm, that appears to work fine with 5.8.1 - admittedly the program doesn't do what I think it should though.

/J\

Well - I'm still on 5.6.1 and don't have the liberty of moving. The documentation says it should work. But it just doesn't work.

I'm on RHEL AS 2.1 - pretty much a glorified and tuned Red Hat Linux 7.3..

The program should create a message queue for the key "24h" with 2000 entries, and then empty it.