Maybe POE might be interesting for you, e.g.

• Tk Interfaces
• Web Server With Components
• Web Server

But I haven't tried to use it in combination with Tk, so this message is just a guess...

Katie, I'll get back to you with the code. Because of all the problems I've had reading from sockets within a GUI, it looks pretty ugly right now. the_wildman

Without seeing your code, it sounds like the socket is blocking. Tk has 2 ways of dealing with it, Tk::Fileevent and Tk::After. You have to let Tk's methods handle the socket reading, so it won't block the "event loop".

Here is an example that was posted awhile back:

#!/usr/bin/perl
use warnings;
use strict;
use Tk;
use Symbol qw(gensym);
use IO::Socket;

$ENV{HOME} = "/" unless $ENV{HOME};

print( "Listening on localhost port 31415.  Telnet to it and try\n",
       "entering something.  In an ideal world, it should echo back.\n
+"
     );

my $acceptor = IO::Socket::INET->new
  ( LocalAddr => '127.0.0.1',
    LocalPort => 31415,
    Listen    => 5,
    Reuse     => 'yes',
  );

my $client = $acceptor->accept();
die "Could not accept a client: $!" unless defined $client;

print "Client connection accepted.\n";

# Turn off buffering. 
select((select($client), $| = 1)[0]);

# Send a welcome message. 

print $client "Hello!\x0d\x0a";

print "Setting callback for $client.\n";
my $main_window = Tk::MainWindow->new();
$main_window->fileevent( $client, 'readable', [ \&read_client ] );
print "Callback set.\n";

Tk::MainLoop();
exit 0;

sub read_client {
  print "Client callback has been invoked.\n";
  my $line = <$client>;
  exit unless defined $line;
  print $client $line;
}
[download]

zentara, I really appreciate your help. This script you have provided is the same as I am using, for the most part. I have the same problem here. The 'fileevent' executes on the event, but only once. I need it to execute on the accept(), move to the callback and then set up for another accept(). I didn't use the telnet part. I send from another socket. That info gets there, once. As the info changes, I want to resend to this server and update the GUI. Or at least that's what I'm trying to accomplish. wildman

#######the server##############################
#!/usr/bin/perl -w
use strict;
use IO::Select;
use IO::Socket;
$| = 1;
# create the socket 

my $host = shift || 'localhost';
my $port = 12345;

my $socket = IO::Socket::INET->new(
       LocalPort => $port,
       LocalAddr => $host,
       Listen    => 5,
       Proto     => 'tcp',
       Reuse     => 1,
      );

defined $socket or die "ERROR: Can't create socket: $!\n";

print STDERR "Socket open ... listening for incoming calls ..\n";

my $select = IO::Select->new($socket);

my %socks;

while (1) {
    foreach my $fh ($select->can_read) {
 if ($fh == $socket) {
     # new connection 
     my $new = $socket->accept;
     $select->add($new);
     $socks{$new}{FH} = $new;
     print STDERR "Received new connection ($new) ..\n";
 } else {
     my $data = <$fh>;
     if (defined $data) {
  $data =~ tr/\r\n//d;

  foreach my $handle (keys %socks) {
      print {$socks{$handle}{FH}} "$handle $data\n";
  }
     } else {
  print "BYE $fh.\n";
  $select->remove($fh);
  delete $socks{$fh};
  $fh->close;
     }
 }
    }
}
[download]

########the client######################
<code>

#!/usr/bin/perl
use warnings;
use strict;
use Tk;
use IO::Select;
use IO::Socket;

require Tk::ROText;

# create the socket 

my $host = shift || 'localhost';
my $port = 12345;

my $socket = IO::Socket::INET->new(
       PeerAddr => $host,
       PeerPort => $port,
       Proto    => 'tcp',
      );

defined $socket or die "ERROR: Can't connect to port $port on $host: $
+!\n";

print STDERR "Connected to server ...\n";

my $mw  = new MainWindow;
my $log = $mw->Scrolled(qw/ROText -scrollbars ose/)->pack;

my $txt = $mw->Entry()->pack(qw/-fill x -pady 5/);

$mw ->bind('<Any-Enter>' => sub { $txt->Tk::focus });
$txt->bind('<Return>' => [\&broadcast, $socket]);

$mw ->fileevent($socket, readable => sub {
      my $line = <$socket>;

      unless (defined $line) {
   $mw->fileevent($socket => readable => '');
   return;
      }

      $log->insert(end => $line);
  });


MainLoop;

sub broadcast {
    my ($ent, $sock) = @_;

    my $text = $ent->get;
    $ent->delete(qw/0 end/);

    print $sock $text, "\n";
}
[download]