Re^3: May Thy Closures Be Blessed

This is probably due to inefficient stringification of the object reference. Maybe the stringified value should be put into the PV portion and POK should be set on while doing Perl_sv_2pv_flags ?

I think this evaluation is spot on. If you change the inside-out implementation to something that avoids stringification:

package Class_Inside_Out;
use Scalar::Util qw(refaddr);
        
my %name;
my %colour;
my %age;
        
sub new {
    my $key        = bless \(my $dummy) => shift;
    $$key          = refaddr ( $key );
    my %args       = @_; 
    $name   {$$key} = $args {name}   || "abigail";
    $colour {$$key} = $args {colour} || "pink";   
    $age    {$$key} = $args {age}    ||  100;
    $key;
}
        
sub name {
    my $key = shift;
    $name {$$key} = shift if @_;
    $name {$$key};
}
        
sub colour {
    my $key = shift;
    $colour {$$key} = shift if @_;
    $colour {$$key};
}

sub age {
    my $key = shift;
    $age {$$key} = shift if @_;
    $age {$$key};
}

sub format {
    my $key = shift;
    join " " => $name {$$key}, $colour {$$key}, $age {$$key};
}
[download]

You get something much more reasonable:

             Rate     closure  inside_out traditional
closure     177/s          --        -43%        -45%
inside_out  313/s         76%          --         -3%
traditional 321/s         81%          3%          --
[download]

Comment on Re^3: May Thy Closures Be Blessed Select or Download Code

Replies are listed 'Best First'.
Re: May Thy Closures Be Blessed by Abigail-II (Bishop) on Apr 26, 2004 at 21:51 UTC
Very nice. Big savings because of caching the calculation of stringified value (I get an 18% difference, not a 3%). Unfortunally, this technique can't be used if you are subclassing a class that doesn't coorperate - then you will to call `refaddr` in each method. That's slower (traditional method being 69% faster), but faster than what I showed before. I would have expected to be able to gain a little more by writing the methods like: `sub name { my $key = ${+shift}; $name {$key} = shift if @_; $name {$key}; }` [download] but that doesn't give me any gain (or loss). Abigail	[reply] [d/l]
Re^2: May Thy Closures Be Blessed by adrianh (Chancellor) on Apr 26, 2004 at 22:37 UTC
I get an 18% difference, not a 3% Hmm. I do seem to have been lucky with my initial runs. I'm seeing between 3-10% on my box, but nothing near 18%. How odd. Unfortunally, this technique can't be used if you are subclassing a class that doesn't coorperate True. Although for hash based objects you could just use one slot for the key and still get safety for all your other state hashes. I would have expected to be able to gain a little more by writing the methods like ... Good point. Can any internals expert explain why `+shift` is so slow?	[reply] [d/l]
Re: May Thy Closures Be Blessed by Abigail-II (Bishop) on Apr 26, 2004 at 22:41 UTC
Although for hash based objects you could just use one slot for the key and still get safety for all your other state hashes. True, but then you make yourself dependent on the implementation of the superclass. It opens the door to collisions, and you get a problem when the superclass changes its implementation (say, it starts to use restricted hashes). Abigail	[reply]


Do you know where your variables are?
	PerlMonks