I think that construct is still legal in Perl 5.8.x but you may be falling foul of use strict;. I may be wrong but I suspect that your $h contains a string which is the name of another variable thus setting up a soft reference. The following have been run under Perl 5.8.4

Firstly with no use strict; or use warnings;

#use strict;
#use warnings;

$h = "fred";
%$h = (name => "Jim", age => 34);
print $h->{name}, "\n";
print $fred{age}, "\n";
[download]

produces

Jim
34
[download]

Switching on strict like this

use strict;
use warnings;

our %fred;
my $h = "fred";
%$h = (name => "Jim", age => 34);
print $h->{name}, "\n";
print $fred{age}, "\n";
[download]

produces

Can't use string ("fred") as a HASH ref while "strict refs" in use at 
+pbeck2 line 8.
[download]

because use strict; objects to soft references. Only by switching strict off for the duration of a code block can you use soft references.

use strict;
use warnings;

our %fred;
my $h = "fred";
{
    no strict q(refs);
    %$h = (name => "Jim", age => 34);
    print $h->{name}, "\n";
}
print $fred{age}, "\n";
[download]

produces

Jim
34
[download]

I hope this clarifies what might be happening with your "illegal" code.

Cheers,

JohnGG

---

---

• Are you posting in the right place? Check out Where do I post X? to know for sure.
• Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:

  <code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>

• Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
• Want more info? How to link or How to display code and escape characters are good places to start.