comment on

You could do

my $iter = get_value_iter($oWkBook);
while ($iter->(my $item_ref)) {
   $$item_ref =~ s/^\s+\n$//;
}
[download]

if you defined get_value_iter as follows:

sub get_value_iter {
   our $val; local *val = \$_[0];

   if (ref($val) eq 'SCALAR') {
      my $ref = $val;
      return sub {
         my $sub_iter = get_value_iter($$ref);
         return $sub_iter->($_[0]);
      };
   }

   if (ref($val) eq 'ARRAY') {
      my $ref = $val;
      my $key = 0;
      my $sub_iter;
      return sub {
         for (;;) {
            return 1 if $sub_iter && $sub_iter->($_[0]);
            return if $key >= @$ref;
            $sub_iter = get_value_iter($ref->[$key++]);
         }
      };
   }

   if (ref($val) eq 'HASH') {
      my $ref = $val;
      my @keys = keys %$ref;
      my $sub_iter;
      return sub {
         for (;;) {
            return 1 if $sub_iter && $sub_iter->($_[0]);
            return if not @keys;
            $sub_iter = get_value_iter($ref->{shift @keys});
         }
      };
   }

   {
      my $ref = \$val;
      my $done = 0;
      return sub {
         return if $done;
         $_[0] = $ref;
         $done = 1;
         return 1;
      };
   }
}
[download]

Scalar::Util's reftype can be used instead of ref if you wish to traverse objects.

In reply to Re^2: iterators: traversing arbitrary data structure by ikegami
in thread iterators: traversing arbitrary data structure by dimar

Are you posting in the right place? Check out Where do I post X? to know for sure.
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>
Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
Want more info? How to link or How to display code and escape characters are good places to start.


P is for Practical
	PerlMonks