comment on

Elijah,
I am sure there is a mathematical equation that would simplify this but I was spending too much time with my TI-89 Titanium trying to figure it out so...

There is an underlying pattern that can be reduced to simple enough instructions to end up with a single array of N² elements populated iteratively. It didn't take me too long to figure it out once I flattened a couple of starting lists with their corresponding solutions

01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16
01 02 03 04 12 13 15 05 11 16 15 06 10 09 08 07

01 02 03 04 05 06 07 08 09 10 11 12 13 14 15 16 17 18 19 20 21 22 23 2
+4 25
01 02 03 04 05 16 17 18 19 06 15 24 25 20 07 14 23 22 21 08 13 12 11 1
+0 09
[download]

You can see the solution below:

#!/usr/bin/perl
use strict;
use warnings;

my $n = $ARGV[0] || 5;
my @spiral = gen_spiral($n);

output(@spiral);

sub output {
    my @spiral = @_;
    my $n = sqrt @spiral;
    my $cnt;
    for ( @spiral ) {
        print "\n" if $cnt++ % $n == 0;
        printf("%-3d ", $_);
    }
}

sub gen_spiral {
    my $n = shift;
    my ($tot, @spiral) = ($n * $n, ());
    my ($index, $cnt, $l_border, $r_border, $fill_size) = (1, 1, 1, $t
+ot, $n + 1);

    while ( $cnt <= $tot ) {

        ##### Moving right #####

        # Step 1, decrease fill size
        --$fill_size;

        # Step 2, fill in
        for ( 1 .. $fill_size ) {
            $spiral[ $index++ ] = $cnt++;    
        }
        --$index;

        # Step 3, skip by n's
        for ( 1 .. $fill_size - 1 ) {
            $index += $n;
            $spiral[$index] = $cnt++;
        }

        ##### Moving left #####

        # Step 1, decrease fill size
        --$fill_size;

        # Step 2, fill in
        for ( 1 .. $fill_size ) {
            $spiral[ --$index ] = $cnt++;
        }

        # Step 4, skip by n's
        for ( 1 .. $fill_size - 1 ) {
            $index -= $n;
            $spiral[$index] = $cnt++;
        }
        ++$index;
    }
    shift @spiral;  # Arrays are 0 based
    return @spiral;
}
[download]

Cheers - L~R

In reply to Re: Spiraling integers by Limbic~Region
in thread Spiraling integers by Elijah

Are you posting in the right place? Check out Where do I post X? to know for sure.
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>
Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
Want more info? How to link or How to display code and escape characters are good places to start.


Perl-Sensitive Sunglasses
	PerlMonks