@rem = '--*-Perl-*--
@pushd .
@pushd > "%TEMP%\editd.txt"
@if defined VISUAL call "%VISUAL%" "%TEMP%\editd.txt"
@if not defined VISUAL notepad "%TEMP%\editd.txt"
@echo - >> "%~f0"
@pushd >> "%~f0"
@popd
@perl -x "%~f0" "%TEMP%\editd.txt"
@if NOT "%OS%" == "Windows_NT" goto endofperl
@if NOT "%COMSPEC%" == "%SystemRoot%\system32\cmd.exe" goto endofperl
@if %errorlevel% == 9009 echo You do not have Perl in your PATH.
@if errorlevel 1 goto script_failed_so_exit_with_non_zero_val 2>nul
@goto endofperl
@rem ';
#!/usr/bin/perl -w
#line 17
use strict;

main( @ARGV );
exit( 0 );

sub main {
    my( $file )= @_;
    my $start= tell(DATA)
        or  die "Can't tell(DATA): $!";
    open DATA, "+< $0"  or  die "Can't read self ($0): $!\n";
    seek( DATA, $start, 0 )
        or  die "Can't fseek(DATA,$start,0): $!";
    die "Expected :endofperl after __END__ of $0.\n"
        unless  <DATA> =~ /^\s*:endofperl\s*$/i;
    $start= tell(DATA)
        or  die "Can't tell(DATA): $!";
    my @curr;
    while(  <DATA>  ) {
        if(  /^\s*-\s*$/  ) {
            @curr= ();
        } else {
            chomp;
            unshift @curr, $_;
        }
    }
    open USER, "< $file"
        or  die "Can't read $file: $!\n";
    my @user= reverse <USER>;
    chomp @user;
    close USER;
    while(  @curr  &&  @user  &&  $curr[0] eq $user[0]  ) {
        shift @curr;
        shift @user;
    }
    seek( DATA, $start, 0 )
        or  die "Can't fseek(DATA,$start,0): $!";
    for(  @curr  ) {
        print DATA "popd\n";
    }
    for my $dir (  @user  ) {
        print DATA qq{pushd "$dir"\n};
    }
    print DATA "pushd\n";
    truncate DATA, tell(DATA);
}
__END__
:endofperl
[download]