comment on

One solution might be to go back to basics and use HTML::Parser, which HTML::TreeBuilder itself uses under the hood.

Although it is not well documented, you can subclass this module and get fine grained control over the parsing, and it will not attempt to make any changes to the document unless you specifically tell it to.

Here is an example which shows how you can combine the parsing with your own transformations:

my $row_html = '<!DOCTYPE html>
<body>
<p>test https://www.google.com</p>
</body>';

my $parser = MyParser->new();
$parser->parse($row_html);
$parser->eof;
print $parser->out;


package MyParser;
use parent qw(HTML::Parser);

sub declaration {
    my ($self, $decl) = @_;
    $self->{'out'} .= "<!$decl>";
}

sub start {
    my ($self, $tag, $attr, $attrseq, $text) = @_;
    if ($tag eq 'p') {
        $self->{'in_para'} = 1;
    }
    $self->{'out'} .= $text;
}

sub text {
    my ($self, $text) = @_;
    if ($self->{'in_para'}) {
        $text =~ s/google/duckduckgo/;
    }
    $self->{'out'} .= $text;
}

sub end {
    my ($self, $tag, $text) = @_;
    if ($tag eq 'p') {
        $self->{'in_para'} = 0;
    }
    $self->{'out'} .= $text;
}

sub out {
    my ($self) = @_;
    return $self->{'out'};
}

1;
[download]

Output:

<!DOCTYPE html>
<body>
<p>test https://www.duckduckgo.com</p>
</body>
[download]

In reply to Re: How to avoid addition of tags by HTML::TreeBuilder by tangent
in thread How to avoid addition of tags by HTML::TreeBuilder by phoenix007

Are you posting in the right place? Check out Where do I post X? to know for sure.
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>
Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
Want more info? How to link or How to display code and escape characters are good places to start.


No such thing as a small change
	PerlMonks