We use an application at $work that uses XML internally for everything. The applications that feed it often wrap the files into a single line, which is a nuisance. vi won't display them, and grep will return the entire file on any match. I've created the code below, based almost entirely on sample code from others, to extract some key information from files.

The first interation (everything below except line 13) worked great until I encountered the namespace prefixes. It didn't take long to find out the solution, but I did not see it implemented in actual code. I guess everybody else thought it was obvious! The Namespaces => 1 in the constructor tells the parser to pull the namespace prefixes from the tag names (they are stored elsewhere), and for my simple example, that's all I need.

Program notes: %interesting is the list of tags the parser will store as it parses the file. The values are stored in the hash %message with the tag as key. In my end handler, I choose a subset of tags based on the document type to display.

#!/home/edi/perl/perl

use strict;
use warnings;
use XML::Parser;

my $parser = new XML::Parser( Handlers => {
        Start   => \&hdl_start,
        End     => \&hdl_end,
        Char    => \&hdl_char,
        Default => \&hdl_def,
        },
        Namespaces => 1);

my (%message,$element);
my %interesting = map { $_, 1 } 
   qw/shipmentStatus responseToLoadTender customerIdentifier proNum lo
+adTenderId eventType eventDate eventTime city seqnum customerId segme
+ntId action date/;
my $file = shift;
$message{file} = $file;
$parser->parsefile($file);
#print "Placeholder\n";

sub hdl_start {
  my ($p,$elt,%attr) = @_;
  $element = $elt;
}

sub hdl_end {
  my ($p, $elt) = @_;
  return unless $interesting{$elt};
  if ($elt eq 'shipmentStatus') {
    if ($message{eventType} !~ m/X6/ ) {
     printf "%-20s: %s\n", $_, $message{$_} 
       for qw/file proNum loadTenderId city seqnum eventType eventDate
+ eventTime/;
     print "\n";
    }
  }
  if ($elt eq 'responseToLoadTender') {
   printf "%-20s: %s\n", $_, $message{$_} 
     for qw/file segmentId loadTenderId action date/;
   print "\n";
  }
}

sub hdl_char { 
  my ($p, $str)  = @_;
  return unless $interesting{$element};
  $message{$element} .= $str;
}
 
sub hdl_def {}
[download]