comment on

Another thing that changed in 2021 (as well as the parallelisation improvements) is that PDL now has native complex numbers, which means the above code could be simplified to using C99 complex numbers rather than manually doing complex-number / magnitude calculations EDIT TO REMOVE size args to pgswin that caused gnuplot to try to make a gigantic window and run out of memory:

use strict;
use warnings;

use PDL;
use PDL::Graphics::Simple;

use Inline Pdlpp => <<'EOPP';
pp_def('pp_mandel',
    # Pars (signature) specs threadable arguments.
    Pars => 'coord(n=2); [o]o(); complex [t]c()',
    # OtherPars specs scalar arguments.
    OtherPars => 'int max_it',
    Code => <<'EOC',
    /* All this code gets wrapped automagically in a thread loop.  */
    /* The $GENERIC(c) macro is the type of ndarray "c".        */
    // using the Wikipedia formula: z_{n+1} = {z_n}^2 + c
    int i;                        // iterator.
    $c() = $coord(n=>0) + I*$coord(n=>1); // Copy the initial value
    $GENERIC(c) z = $c(); // Copy for the initial iteration
    // the OtherPars are in the $COMP macro.
    for(i=$COMP(max_it); cabs(z) < 2 && i; i--)
        z = z*z + $c();
    $o()= i; // Assign the iterator to the output value
EOC
);
EOPP

my $cen = pdl(-0.74897,0.05708);
my $coords = $cen + (ndcoords(501,501)/250 - 1) * 0.001;
my $w = pgswin();

$w->image( $coords->using(0,1), $coords->pp_mandel(2500),
  {title=>"Mandelbrot"} );

<STDIN>
[download]

EDIT apparently this version takes twice as long to run as the one that doesn't use C99 complex numbers. I assume this is because mine uses cabs, while the other one uses some cleverness to reduce the amount of multiplications etc.

In reply to Re^3: [OT] Merry Christmas and gift of love by etj
in thread [OT] Merry Christmas and gift of love by marioroy

Are you posting in the right place? Check out Where do I post X? to know for sure.
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>
Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
Want more info? How to link or How to display code and escape characters are good places to start.


Just another Perl shrine
	PerlMonks