I'm having trouble understanding your inputs because I'm not sure how many backslashes the strings actually contain, for example in '1,This is a problem->\\,B,2' this string actually contains only one backslash, where you probably meant two. And in my $regex = '(?<!\\\),';, the string actually only contains two backslashes because '\\' becomes \ but '\)' remains as \) (see Quote Like Operators).

My suggestion is to use double quotes for strings, since those will force you to escape all backslashes that you want to appear in the string, and so it'll be less confusing. For regexes, definitely use qr// instead of quotes (that's the reason for your "Unrecognized escape \Q passed through in regex" problem). For looking at the strings you've got and showing them to us, use either Data::Dumper with $Data::Dumper::Useqq=1;, or Data::Dump.

Your question is also inconsistent in that you say "2 character hex codes '\x2B'" but then show '\0x2B' in the string.

Anyway, one approach to this task is Text::CSV, like what jo37 showed. However, if I understand your requirement "2 character hex codes" correctly, does this mean that your input string could be "1,Something\\,\\\\text\\\\text\\x2B\\\\,X,99" and you want the output to be ("1","Something,\\text\\text+\\","X","99")? (Next time please show your expected output as well!)

Although if we're lucky, Tux might enlighten us to the correct options for Text::CSV_XS to handle this case, in the meantime one possible solution is to write a somewhat-decent parser to your specification.

use warnings;
use strict;

sub parse {
    local $_ = shift;
    my @out = ('');
    pos=undef;
    while (1) {
           if ( m{\G , }xgc ) { push @out, '' }
        elsif ( m{\G \\x([0-9a-fA-F]{2}) }xgc )
            { $out[-1] .= chr hex $1 }
        elsif ( m{\G (?| \\([,\\]) | ([^,\\]+) ) }xgc )
            { $out[-1] .= $1 }
        else { last }
    }
    pos==length or die "parse of '$_' failed at pos ".pos;
    return @out;
}

use Test::More tests=>1;
my @o = parse "1,Something\\,\\\\text\\\\text\\x2B\\\\,X,99";
is_deeply \@o, ["1","Something,\\text\\text+\\","X","99"];
[download]