Beefy Boxes and Bandwidth Generously Provided by pair Networks
The stupid question is the question not asked
 
PerlMonks  

A cacheing tied hash base class

by rdw (Curate)
on Sep 13, 2000 at 05:17 UTC ( #32233=snippet: print w/replies, xml ) Need Help??
Description: After a long and helpful discussion in the Chatterbox, I hacked this together. It's a base class which lets you build a hash that fills itself 'on demand'.
#! /usr/bin/perl -w

package Tie::AutoCache;

use strict;
use vars qw(@ISA);

use Tie::Hash;

@ISA = qw(Tie::StdHash);

sub TIEHASH {

  my($class) = shift;
  my($self) = { };
  bless $self, $class;
}

sub FETCH {

  my($self, $key) = @_;

  unless (exists $self->{$key}) {
    if ($self->can($key)) {
      $self->{$key} = $self->$key();
    }
    else {
      warn "No method for '$key'";
      $self->{$key} = undef;
    }
  }
  return $self->{$key};
}

1;

#########################################################

package Thingy;

use vars qw(@ISA);

@ISA = qw(Tie::AutoCache);

sub new {

  my($class) = shift;
  my(%hash);
  tie %hash, $class;
  return \%hash;
}

sub foo {

  my($self) = @_;
  $self->{bar} = "this is bar\n";
  return "this is foo\n";
}

1;

#########################################################

package main;

my($thingy) = new Thingy();

print $thingy->{foo};
print $thingy->{bar};
print $thingy->{not};
Replies are listed 'Best First'.
RE: A cacheing tied hash base class
by merlyn (Sage) on Sep 13, 2000 at 05:46 UTC
    Very cool! But you can save the double lookup easily:
    sub FETCH { my($self, $key) = @_; unless (exists $self->{$key}) { if (my $meth = $self->can($key)) { $self->{$key} = $meth->($self); } else { warn "No method for '$key'"; $self->{$key} = undef; } } return $self->{$key}; }
    That's because $obj->can('meth') returns the coderef to execute!

    -- Randal L. Schwartz, Perl hacker

Log In?
Username:
Password:

What's my password?
Create A New User
Node Status?
node history
Node Type: snippet [id://32233]
help
Chatterbox?
and the web crawler heard nothing...

How do I use this? | Other CB clients
Other Users?
Others lurking in the Monastery: (4)
As of 2021-01-20 06:59 GMT
Sections?
Information?
Find Nodes?
Leftovers?
    Voting Booth?
    Notices?