foo($bar,$baz,@qux);

sub foo
{
  my $bar = shift;
  my $baz = shift;
  my @qux = @_;
  # or my($bar,$baz,@qux)=@_;
}
[download]

foo(\@arr1,\@arr2);

sub foo
{
  my @arr1=@{+shift};
  my @arr2=@{+shift};
}
[download]

You need to pass the array by reference rather than by value. This section of perlsub explains it better than I can.

my %hash = ( 'This'  => 1,
             'That'  => 2,
             'Other' => 3 );
my @array = ( 1, 2, 3, 4, 5 );
my $scalr = "Hello World!\n";

mytest ( \%hash, \@array, $scalr );

sub mytest {
    my $h_ref = shift;
    my $a_ref = shift;
    my $simple = shift;
    local $, = ", ";
    print $h_ref->{$_}, "\n" foreach keys %{$h_ref};
    print $_, "\n" foreach @{$a_ref};
    print $simple, "\n";
}
[download]

Take a look at perlreftut and perlsub for a more detailed description, and clever examples.

You have several ways to go for this. Pick one that fits what you want.

Inside the sub, you can say

sub CallSub {
    my ($IGot, $TheBlues, @Array) = @_;
# or
    #(my $IGot, my $TheBlues, @_) = @_;
# or else shift the first two in
    # my ($IGot, $TheBlues) = (shift, shift);
    # ...
}
[download]

Another way is to pass in an array reference, either explicitly, or by defining CallSub with a prototype of ($$\@). In either case you would do that like this,

sub CallSub
# ($$\@)  # if you choose
{
    my ($IGot, $TheBlues, $Arrayref) = @_;
    # or some variation
    # ...
}
[download]

$Igot = 'whatever';
$TheBlues = 'whateverelse';
@Array = 'la la la laaaa';
CallSub($Igot, $TheBlues, @Array);

sub CallSub {
    my $Igot = shift;
    my $TheBlues = shift;
    my @Array = @_;
    ....
}
[download]

Callsub($number, \@Somearray, \@Otherarray);
sub Callsub {
    my $number = shift;
    my @array = @{ +shift };
    my @array2 = @{ +shift };
    ....
}
[download]

There were no other replies when I posted this.  Really.  :)

You can set a prototype on your function to automatically change @Array to \@Array in the caller, but I don't recommend that unless you know what you are doing; people often misunderstand what prototypes are actually for and expect more (or less) than they actually do.

recurse(split('','Hello World'));

sub recurse {
    my ($car,@cdr) = @_;
    print "$car\n";
    @cdr and recurse(@cdr);
}
[download]

foo(
   array  => [0..9],
   scalar => 'Hello World',
   hash   => {qw(foo bar baz qux)},
);

sub foo {
   my %args = @_;
   print 's: ', $args{scalar},"\n",
      'a: ', join(',', @{$args{array}}),"\n",
      "h:\n", map "\t$_ => $args{hash}{$_}\n", keys %{$args{hash}},
   ;
}
[download]

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

my $scalar1 = 1;
my $scalar2 = 2;

($scalar1,$scalar2) = my_subroutine(@array1,$scalar1,$scalar2);
print "$scalar1 $scalar2 \n";

sub my_subroutine() {
   @array1 = @{shift()};
   $scalar1 = shift();
   $scalar2 = shift();

   $scalar1 =+ 22;
   $scalar2 =+ 33;

return ($scalar1,$scalar2);
}
[download]

my @array1 = (1,2);
$arrayref = \array1;
($arrayref,$scalar1,$scalar2,$hashref) = my_sub(@array1,$scalar1,$scal
+ar2);

@array1 = @{$arrayref};
my %hash = %{$hashref};

print "$array[0]\n";
print "$hash{name}\n";


sub my_sub() {
   @array = @{shift()};
   $s1 = shift();
   $s2 = shift();

   my %hash = {'name'=>'a', 'city'=>'b'};
   $array[0]  =3;
   $hash{name} = 'aaa';
return (\@array1,$scalar1,$scalar2,\%hash);
}
[download]

Err -- whoa there. There are a few problems with this code. First off, let me clean it up a little (such as actually passing it an array with some elements in it) and feed it though with -w -Mstrict

my @array = (42,43,44,45);
my $scalar1 = 1;
my $scalar2 = 2;

($scalar1,$scalar2) = my_subroutine(@array,$scalar1, $scalar2);
print "$scalar1 $scalar2\n";

sub my_subroutine() {
  my @a = @{shift()};
  my $s1 = shift();
  my $s2 = shift();

  print "array: @a\ns1: $s1\ns2: $s2\n";
  $s1 += 22;
  $s2 += 33;
  return ($s1, $s2);
}
[download]

..to which perl says:

main::my_subroutine() called too early to check prototype at - line 5.
Can't use string ("42") as an ARRAY ref while "strict refs" in use at 
+- line 9.
[download]

..which shows the two most glaring bugs in the code. First off, you've given your subroutine a prototype, which only works if your calls to the subroutine are after its declaration. If you move the subroutine to above the call, however, we discover that you're giving the wrong prototype, anyways! (Too many arguments for main::my_subroutine at - line 15, near "$scalar2)")

You're also passing in an array, and trying to treat it as an array reference in the code. That's what the second error message is telling you.

These are all vaguely fixable by changing your code to:

sub my_subroutine(\@$$) {
  my @a = @{shift()};
  my $s1 = shift();
  my $s2 = shift();

  print "array: @a\ns1: $s1\ns2: $s2\n";
  $s1 += 22;
  $s2 += 33;
  return ($s1, $s2);
}
my @array = (42,43,44,45);
my $scalar1 = 1;
my $scalar2 = 2;

($scalar1,$scalar2) = my_subroutine(@array,$scalar1, $scalar2);
print "$scalar1 $scalar2\n";
[download]

..but don't do that, as prototypes are mostly broken and confusing. This public service announcement has been brought yo you by the letter P and the number 42.

Networking -- only one letter away from not working

Thanks for all the input, suggestions, and prompts on what and where to look