Your treatment of references here is completely correct. The problem with the code is that sub capitalize does not actually change anything in the hash passed to it, as well as having argument passing problems. If you want to change the keys of the hash, try this,

sub capitalize {
    my $hashref = shift;
    foreach ( keys %$hashref ) {
        $hashref->{ uc($_) } = delete $hashref->{$_};
    }
    1;
}
[download]

#!/usr/bin/perl -w
use strict;

my %horoscopes = (
    'homer' => 'pisces',
    'marge' => 'sagitarius',
    'bart'  => 'cancer',
    'libra' => 'libra'
);

capitalize(\%horoscopes);

sub capitalize {
    my $hash = shift;
    for my $key (keys %{$hash}) {
        $hash->{uc $key} = $hash->{$key};
        delete $hash->{$key};
    }
}
[download]

Cheers - L~R

Perl subroutines are always call-by-reference.

my $a = 10;

print "$a ";
change($a);
print "$a";

sub change {
    $_[0]++;
}
[download]

The standard practice of making copies of the subroutine parameters functionally turns this into call-by-value.

my $a = 10;

print "$a ";
change($a);
print "$a";

sub change {
    my $param = shift;
    $param++;
}
[download]

But if you're passing an explicit reference, then a copy of the reference still refers to the original referent.

# contrived example: there usually isn't a good reason
# to have references to scalars.
my $a = 10;
my $b = \$a;

print "$$b ";
change($b);
print "$$b";

sub change {
    my $param = shift;
    ${$param}++;
}
[download]

...but the subroutine parameter was still an alias of the original reference, and so its value (not just the referent's value) can be changed, just as in the first example.

my $a = 10;
my $b = \$a;
my $c = 4;
print "$$b ";
change($b);
print "$$b";

sub change {
    $_[0] = \$c;
}
[download]

You usually won't write code like the first or last examples -- but it's good to understand all this.

&capitalise( \%horoscopes );

sub capitalise {
  my $values = shift;
  foreach ( keys ( %{$values} ) ) {
  ....
...this is not tested...
[download]