Assuming that there are no _extra_ commas or equal signs besides the ones that separate key/value pairs and separate the keys from the values, ...

my @stuff;
while (<FILEHANDLE>) {
  chomp;
  push @stuff, { map {split /\s*=\s*/} split /,\s*/ }
}
[download]

But don't just copy this code if you don't understand it, especially if this is going into something you'll have to maintain. Let's break that down into something more verbose...

Also, be aware that if there are any anomalies in the input, such as any missing or extra commas or equal signs, this code will produce quite strange results. I believe there is an extra argument you can optionally pass to split to limit the number of pieces it will split things into, which may be of value here. I'd look it up, but my camel is at home and I'm not. Perhaps someone else can reply and confirm whether it is the third argument as ISTR.

$;=sub{$/};@;=map{my($a,$b)=($_,$;);$;=sub{$a.$b->()}}
split//,".rekcah lreP rehtona tsuJ";$\=$ ;->();print$/
[download]

Thanks, that helps. I was working somewhat along these lines already but wasn't quite getting things put into the right spots. I'll poke around a bit more with this as the days go by (this is really a side project that I'm working on when I get frustrated with other things :)

---

"Ex libris un peut de tout"

#!/usr/local/bin/perl5.6.0 -w
use strict; 

use Data::Dumper;

my @records;

while ( my $entry = <DATA> )
{
    my %rec = map { /(\S+)\s*=\s*([^\n\r]+)$/ } 
              split( /,/, $entry );

    push( @records, \%rec );
}

print Dumper( \@records );


__DATA__
Field1= a value,Field2= another value, Field3= yet another value
Field1= a value,Field2= another value, Field3= yet another value
Field1= a value,Field2= another value, Field3= yet another value
[download]

Best Regards,
Wonko

    my @data = map {chomp; +{/([^=]+)=([^,]+),?/g}} <>;
[download]

Abigail

The while loop loops over your data, and the split breaks your line into a list of comma- and equal sign-separated items.

This list is then converted into an anonymous hash with the {} operator, and that hash is pushed onto the array @structure.

Note that this will work incorrectly if your values or field names have "="s or ","s in them.

#!perl
use warnings;
use strict;
use Data::Dumper;

my @structure;

while (<DATA>) {
    chomp;
    push @structure, { split /,|=/ };
}

print Dumper \@structure;

__DATA__
Field1= a value,Field2= another value, Field3= yet another value
Field1= a second value,Field2= another second value, Field3= yet anoth
+er second value
[download]

Hi nimdokk

You could try something like

#!/usr/bin/perl

use strict;
use warnings FATAL => 'all';
use Data::Dumper;

open DATA, "filename" or die $!;

my @AoH;

for (<DATA>){
    
    my %hash;
    %hash = map { split '=' } split ',';

    push @AoH, \%hash;
}

print  Dumper \@AoH;
[download]

cheers

thinker

#!/usr/local/bin/perl -w
use strict;
use Data::Dumper;

my %records;
while ( <DATA> ) {
   chomp;
   while ( m| (\w+)\s* = \s*([^,]+)\s* |gx ) {
      $records{$1} = $2;  # add to hash
   }
}
print Dumper( \%records );


__DATA__
F1=D1, F2 = D2, F3= D3, F4 =D4,  F5  =  D5
[download]

$VAR1 = {
          'F2' => 'D2',
          'F3' => 'D3',
          'F4' => 'D4',
          'F5' => 'D5',
          'F1' => 'D1'
        };
[download]