Is the data of fixed width? If so, you're better off with unpack:

# @LIST_OF_ENTRIES contains your data, one line per element
my %description_hash;
foreach my $entry (@LIST_OF_ENTRIES) {
    # Replace 20 with the number of characters in the value portion
    my ($value, $name) = unpack('A20 A*', $entry);
    $value =~ s/\A\s*//;
    $value =~ s/\s*\z//;
    $description_hash($name} = $value;
}
[download]

----
I wanted to explore how Perl's closures can be manipulated, and ended up creating an object system by accident.
-- Schemer

Note: All code is untested, unless otherwise stated

Hi - Thanks for the help. I don't understand the \A in s/\A\s*// however. Can you explain it to me?

$ perldoc perlre
[download]

The \A anchors the search at the beginning of the string. A ^ anchors a search at the beginning of the LINE in a string. Documentation is a wonderful thing.

--
[ e d @ h a l l e y . c c ]

my ($desc,$code) = unpack("A60 A*",$line);#or however long 1st field i
+s.
$description_hash{$code}=$desc;
[download]

This does the trick.

#! perl -slw
use strict;

my %desc;

m[^\s*(.*?)\s+([A-Z0-9]+)\s+(?:[0-9,]+\s*)?$]
    and $desc{ $2 } = $1
    while <DATA>;

my $code = 'GMF';
print "$code : $desc{ $code }";

__DATA__
Total index                                              B50001
 Crude processing (capacity)                             B5610C
 Primary & semifinished processing (capacity)            B562A3C
 Finished processing (capacity)                          B5640C
 Manufacturing ("SIC")                                   B00004
  Manufacturing (NAICS)                                  GMF
   Durable manufacturing (NAICS)                         GMFD
    Wood product                                         G321         
+    321
    Nonmetallic mineral product                          G327         
+    327
    Primary metal                                        G331         
+    331
     Iron and steel products                             G3311A2      
+    3311,2
    Fabricated metal product                             G332         
+    332
    Machinery                                            G333         
+    333
[download]

use strict;

my $str = <<TXT;
Total index                                              B50001
 Crude processing (capacity)                             B5610C
 Primary & semifinished processing (capacity)            B562A3C
 Finished processing (capacity)                          B5640C
 Manufacturing ("SIC")                                   B00004
  Manufacturing (NAICS)                                  GMF
   Durable manufacturing (NAICS)                         GMFD
    Wood product                                         G321         
+    321
    Nonmetallic mineral product                          G327         
+    327
    Primary metal                                        G331         
+    331
     Iron and steel products                             G3311A2      
+    3311,2
    Fabricated metal product                             G332         
+    332
    Machinery                                            G333         
+    333
TXT

my(%hash, %numbers);
for(split "\n" => $str) {
  my @fields = reverse split;
  $numbers{$fields[1]} = shift @fields
    if $fields[0] =~ /\d(?:,\d+)?/;
  $hash{$fields[0]} = join ' ' => reverse @fields[1 .. $#fields];
}

my $code = 'GMF';

print "$code: $hash{$code}.\n";

__output__

GMF: Manufacturing (NAICS).
[download]

_________
broquaint

That doesn't work. Many of the text descriptions have spaces in them, plus there's spaces at the beginning of most of the lines.

As this is fixed length, use unpack. Now, you're going to have to also use some logic if you care about the indenting stuff to make sure that you don't keep that whitespace at the beginning of your description. If you don't, it's easy enough to strip off the indenting whitespace. To get what you exactly wanted, do something like:

# Change these to the actual column widths. Use a star at the end to g
+et the rest.
my @column_widths = (###, ###, '*');
my $unpack_spec = join ' ', map { "A$_" } @column_widths;

my %codes;
while (<IN_FILE>)
{
    chomp;
    my ($desc, $code, $other_thingy) = unpack $unpack_spec, $_;

    # If you want to remove the pre-pended whitespace on the descripti
+on ...
    $desc =~ s/^\s+//;

    $codes{$code} = {
        Description => $desc,
        Other_Thing => $other_thingy,
    };
}

my $choice = 'GMT';
print "$choice: $codes{$choice}{Description}\n";
[download]

------
We are the carpenters and bricklayers of the Information Age.

The idea is a little like C++ templates, except not quite so brain-meltingly complicated. -- TheDamian, Exegesis 6

Please remember that I'm crufty and crochety. All opinions are purely mine and all code is untested, unless otherwise specified.

What would you be wanting to use as the key? I might imagine at least three possibilities:

• everything in those fixed columns, thus 'G3311A2     3311,2' including the spaces between the strings,
• just one part of all that, such as just 'G3311A2',
• both parts individually as alternate keys 'G3311A2' and '3311,2'

dragonchild uses $other_thingy to capture the '3311,2' separately. But what really should be done with that part?

You're right; I was ambiguous. For this line:

Iron and steel products       G3311A2     3311,2
[download]

The key should be 'G3311A2' and the value should be 'Iron and steel products'. The '3311,2' information is not needed by me.

So if the data format really _is_ fixed-width columns then something like dragonchild's code would work, using

  my @column_widths = (57, 17, '*');
[download]

for the widths (check against the real column widths).   Although to remove the leading _and_ trailing spaces from each piece I'd do something like:

  my ($desc, $code, $other_thingy) = unpack $unpack_spec, $_;
  foreach my $piece ($desc, $code, $other_thingy) {
    $piece =~ s/^\s+//;
    $piece =~ s/\s+$//;
  }
[download]

(I think that's right, hmmm, testing with dragonchild's modified code ....)

# Change these to the actual column widths. Use a star at the end to g
+et the rest.
my @column_widths = ( 57, 17, '*');
my $unpack_spec = join ' ', map { "A$_" } @column_widths;

my %codes;
while (<DATA>)
{
    chomp;
    my ($desc, $code, $other_thingy) = unpack $unpack_spec, $_;
    foreach my $piece ($desc, $code, $other_thingy) {
      $piece =~ s/^\s+//;
      $piece =~ s/\s+$//;
    }

    $codes{$code} = {
        Description => $desc,
        Other_Thing => $other_thingy,
    };
}

my  $choice = 'GMF';
print "$choice: $codes{$choice}{Description}\n";
    $choice = 'G3311A2';
print "$choice: $codes{$choice}{Description}\n";

__DATA__
Total index                                              B50001
 Crude processing (capacity)                             B5610C
 Primary & semifinished processing (capacity)            B562A3C
 Finished processing (capacity)                          B5640C
 Manufacturing ("SIC")                                   B00004
  Manufacturing (NAICS)                                  GMF
   Durable manufacturing (NAICS)                         GMFD
    Wood product                                         G321         
+    321
    Nonmetallic mineral product                          G327         
+    327
    Primary metal                                        G331         
+    331
     Iron and steel products                             G3311A2      
+    3311,2
    Fabricated metal product                             G332         
+    332
    Machinery                                            G333         
+    333

_ _ OUTPUT _ _ 

GMF: Manufacturing (NAICS)
G3311A2: Iron and steel products
[download]

#!/usr/bin/perl -w

use strict;

my %hash;
while (<DATA>) {
   s/^\s+//;  # remove leading whitespace
   if ( /(.*?)\s{3,}(\S+)/ ) {
      my ($val,$key) = ($1,$2);
      $hash{$key} = $val;
   }
}
print map { "$_ : $hash{$_}\n" } sort keys %hash;

__DATA__
Total index                                              B50001
 Crude processing (capacity)                             B5610C
 Primary & semifinished processing (capacity)            B562A3C
 Finished processing (capacity)                          B5640C
 Manufacturing ("SIC")                                   B00004
  Manufacturing (NAICS)                                  GMF
   Durable manufacturing (NAICS)                         GMFD
    Wood product                                         G321         
+    321
    Nonmetallic mineral product                          G327         
+    327
    Primary metal                                        G331         
+    331
     Iron and steel products                             G3311A2      
+    3311,2
    Fabricated metal product                             G332         
+    332
    Machinery                                            G333         
+    333

__OUTPUT__
B00004 : Manufacturing ("SIC")
B50001 : Total index
B5610C : Crude processing (capacity)
B562A3C : Primary & semifinished processing (capacity)
B5640C : Finished processing (capacity)
G321 : Wood product
G327 : Nonmetallic mineral product
G331 : Primary metal
G3311A2 : Iron and steel products
G332 : Fabricated metal product
G333 : Machinery
GMF : Manufacturing (NAICS)
GMFD : Durable manufacturing (NAICS)
[download]