You need to use string comparison in line 6:                       if ($key eq $thing)   { However, it would be better to check existence of the array element as a hash key, exists $hash{$_} and push @new_array, $hash{$_} for @array; replaces the whole thing. That could be done with map and grep, too: my @new_array = map {$hash{$_}} grep {exists $hash{$_}} @array; or a slice with grep, my @new_array = @hash{ grep {exists $hash{$_}} @array };

After Compline,
Zaxo

It probably doesn't work right because you're using the numeric comparison operator (==) on data that is probably strings. You should have used eq instead. But that's not all that you need to fix.

The first thing that comes to mind when I look at your code is that you're not really taking advantage of true power of hashes. Instead of walking through the hash and comparing $thing to $key, you want to use $thing as the key, like this:

foreach my $thing (@array) {
    if(exists $hash{$thing}) {
       push @new_array, $hash{$thing};
    }
}
[download]

If you're not afraid of grep, try this:

my @new_array = grep { exists $hash{$_} ? $hash{$_} : 0 } @array;
[download]

But that will fail if %hash contains false values.

Update: Was using $thing in the grep when I should have used $_. Thanks to davorg.

----
I wanted to explore how Perl's closures can be manipulated, and ended up creating an object system by accident.
-- Schemer

Note: All code is untested, unless otherwise stated

Much easier with grep.

@new_array = @hash{ grep { exists $hash{$_} } @array };
[download]

"The first rule of Perl club is you do not talk about Perl club."
-- Chip Salzenberg

I was going to suggest:

   my @ary2 = grep {defined} @hash{@ary};
[download]

It's tempting to just say   my @ary2 = @hash{@ary}.   But the values in @ary that don't match keys in %hash produce undefined values that have to be weeded out.

Here's a quick demo:

#!/usr/bin/perl -w
use strict;

my @ary  = ('a', 'c', 'g', 'l');
my %hash = (a => 1, b => 2, c => 3, d => 4);

my @ary2 = grep {defined} @hash{@ary};

print "[$_]\n" for @ary2;
[download]

foreach my $thing (@array) {
    if ( exists $hash {$thing} ) {
        push @new_array, $hash {$thing};
    }
}
[download]

hope this helps,