$variables{variable_name} = get_page_content("names");
[download]

Please please get yourself a copy of Learning Perl, it'll pay off :)

To assign an individual key/value pair try:

$hash{'key1'} = 4;
$hash{'key2'} = 5;
[download]

There are plenty of resources for learning Perl:

Generally speaking, if you are getting variable name/value pairs then adding them to the hash is simply a matter of:

$variables{$varname}=$varvalue;
[download]

Because you mention that you don't want to delete variables that are already there, I wonder if you mean that some of the variables you are reading in may already be in the hash. If that is the case, you can make sure they are not in the hash by doing something like this when you assign the values:

$variables{$varname}||=$varvalue;
[download]

That little ||= keeps a value in the hash if it is there or assigns a new key/value pair if it is not defined yet.

The question here is: What exactly is get_page_content() returning? A scalar? array? reference? If you can tell us this, we can give you a more specific anwer.

Cheers

That little ||= keeps a value in the hash if it is there or assigns a new key/value pair if it is not defined yet.

Oops. You have to be a little more careful than that. Your code will perform the assignment even in the case that a previous false value exists. For example:

$h{key} = 0; 
$h{key} ||= "foo"; 
print $h{key};
[download]

If you really want to check for definedness, you should use defined(). Often, though, there are situations where undef is a valid value too and in those cases you should use exists() to check whether the hash key exists yet. Here is one way to do that succinctly:

$h{$key} = "value" unless exists $h{$key};
[download]

-sauoq
"My two cents aren't worth a dime.";

Not unless get_page_content("names") returns a key-value paired list.

Plus, that's just a silly way of doing it.

sub pushhash (\%@) {
  my $hash = shift;
  my $key;
  $$hash{$key} = shift while defined($key = shift);
}

my %a;

$a{cow} = "COW1";
$a{dog} = "DOG1";

pushhash %a, cow => "COW2", bull => "Terrier";

for (sort keys %a) {
  print "$_ => $a{$_}\n";
}
[download]

  %variables = (%variables, get_page_content("names"));
[download]

Not unless get_page_content("names") returns a key-value paired list. Plus, that's just a silly way of doing it.

------
We are the carpenters and bricklayers of the Information Age.

Don't go borrowing trouble. For programmers, this means Worry only about what you need to implement.

Please remember that I'm crufty and crochety. All opinions are purely mine and all code is untested, unless otherwise specified.

sub get_page_content {
    my $type = shift;

    my $dbh = DB_File::connect();
    $sth = $dbh->prepare (qq{ SELECT `name`,`value` FROM `page_variabl
+es` WHERE `type` = ? });
    $sth->execute($type);
    my %temp_vars; # WILL THIS KILL THE REST OF THE VALUES?
    while(my ($db_name,$db_content) = $sth->fetchrow_array()) {
        $temp_vars{$db_name} = $db_content;
    }
    $sth->finish();

return(%temp_vars);
}
[download]

Remember that = is an assignment operator, not an addition or concatenation operator. When you use it, you are telling Perl to set the left-hand side equal to the right-hand side. All entries in the hash will be replaced.

You have two options: You can either iterate through the replacement key/value pairs and set the $hash{$key} = $value, or if your list of keys and values are known ahead of time, a hash slice might let you make a change to a group of hash entries with one statement (e.g. @hash{@new_keys} = @new_values).

my $temp_vars;
[download]

my ($type,%temp_vars) = @_;
[download]

That would work, but it would be more efficient to pass the hash by reference:

get_page_content(\%variables, "names");
  # instead of %variables = get_page_content("names");

sub get_page_content {
    my ($hashref, $type) = @_;


    my $dbh = DB_File::connect();
    $sth = $dbh->prepare (qq{ SELECT `name`,`value` FROM `page_variabl
+es` WHERE `type` = ? });
    $sth->execute($type);
    while(my ($db_name,$db_content) = $sth->fetchrow_array()) {
        $$hashref{$db_name} = $db_content;
    }
    $sth->finish();

}
[download]

Tom Christiansen, the author of the well-worth reading FMTEYEWtKaPiP shows this neat function.

    sub hpush(\%@) {
        my $href = shift;       # NB: not %
        while ( my ($k, $v) = splice(@_, 0, 2) ) {
            $href->{$k} = $v;
        }
    }
[download]

Which you could use to this

    hpush(%variables, get_page_content("names"));
[download]

# This would be the return statement of get_page_content
return \%temp_vars;

# And this would be the call:
$new_variables = get_page_content("names");

# $new variables is a reference to your result
@variables{keys %$new_variables}=values %$new_variables;
[download]