Yet Another Scratchpad Downloader

This little program grabs a user's homenode using the XML displaytype, extracts the scratchpad contents, and displays it on STDOUT. The user's name is taken from the command line. Redirection can be used to save to a file.

Other similar programs I found with super search:

download code from scratchpad by crazyinsomniac
This one extracts from Scratchpad Viewer.
Scratch Pad Poster by jeffa
Allows reading and writing your own scratchpad.
hup (homenode updater) by ar0n
Allows updating various portions of your homenode.

Uses URI, LWP::Simple, and XML::Simple.

#!/usr/bin/perl -w
#
# getpad.pl
# author: [pfaut]
# download code from a perlmonks user's scratchpad
#
# Usage: perl getpad.pl username
#
# extracts the scratchpad contents from the xml representation of
# the user's homenode and writes it to STDOUT
#

use strict;
use URI;
use LWP::Simple;
use XML::Simple;

my $user = shift;
if (!$user) {
    print "Usage: $0 <username>\n";
    exit;
}
my $uri = URI->new("http://www.perlmonks.org/index.pl");
$uri->query_form(node=>$user,type=>"user",displaytype=>"xml");
my $xml = get($uri)
    or die "Unable to access page";
my $parsed = XMLin($xml);
die "$user is not a user\n"
    unless $parsed->{type}{content} =~ /\buser\b/;
my $pad = $parsed;
for (qw(data field scratchpad content)) {
    die "${user}'s scratchpad unavailable\n"
    unless exists $pad->{$_};
    $pad = $pad->{$_};
}
$pad =~ s/^\r?\n//;
print $pad;
[download]

Back to Cool Uses for Perl