I'd do it like this:

The INI

[GENERAL]
scheduledb=something
[SERVICE]
start2=stuff ${GENERAL/scheduledb=default} etcetera
[download]

The "getter":

sub x_val {
  my ($ini,$sect,$key,$def)=@_; # same signature as 'val'
  my $val=$ini->val($sect,$key,$def);
  my ($sect1,$key1,$def1,$t);
  while ($val=~/\$\{([^}]+)\}/) {
   $t=$1;
   ($sect1,$key1,$def1)=($t=~m|^([^/]+)/([^=]+)(?:=(.*))?$|);
   $val=$`.(x_val($ini,$sect1,$key1,$def1)).$';
  }
 $val;
}
[download]

Notes:

• It uses pre- and post-match variables, so it will slow you regexps
• The syntax is a bit different from the one you show
• It expands recursively
• It supports in-line defaults
• I haven't tested it...

-- 
        dakkar - Mobilis in mobile

If you would not insist on Config::IniFile ...

use Config::IniHash;

$config = ReadINI( 'Service.ini',
  systemvars => 0,
    # do not expand system %variables%
  case => 'preserve', 
    # lookup is case insensitive. keys %$INI return the original case
    # ! if you change this option to a case sensitive one even the %se
+ction-name% variables will be case sensitive !
  forValue => sub {
    my ($name, $value, $sectionname, $INI) = @_;
    $value =~ s/%(\w+)-(\w+)%/$INI->{$1}->{$2}/g;
    return $value;
  },
);

use Data::Dumper;
print Dumper($config);
[download]

As you see you get a HoH containing the data from the INI file and you can "preprocess" the values before inserting them to the HoH.

HTH, Jenda

P.S.: To continue the shameless plug ... did you consider using PerlApp and Win32::Daemon::Simple?

 $config->{general-schedule} = $general-schedule-config
[download]

You can also use do to accomplish the same thing. Here is a simple example:

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

our $config;

do '/tmp/config.pl';

print Dumper(\$config),"\n";
[download]

and /tmp/config.pl looks like:

$config = [
  option1 => 'one',
  option2 => 'two',
  option3 => 'three'
];
[download]

It might also be advantagous to setup a signal handler (or whatever means/mechanism available as a win service) that will reread the config.


cp
----
"Never be afraid to try something new. Remember, amateurs built the ark. Professionals built the Titanic."

If you are not stuck using Config::IniFile and can switch to Config::General, then you get variable substitution built in.

use Config::General;
use Data::Dumper;

$conf = new Config::General(
                -ConfigFile => 'y.cfg',
                -InterPolateVars => 1,
                );

my %config = $conf->getall;

print Dumper(\%config);

__END__


# config file contents

# GENERAL
# scoping allows substituting in the same block or
# a nested block, see N.B. below.
scheduledb=e:\users\dbush\schedule.db

<SERVICE>
debug=1
interval=5
start1=browser.exe;browser;NORMAL_PRIORITY_CLASS
start2=schedule.exe;schedule "localhost:$scheduledb";NORMAL_PRIORITY_C
+LASS
</SERVICE>


########### Output: $VAR1 = \%config
### note how $scheduledb is substituted into 'start2'
$VAR1 = {
          'SERVICE' => {
                         'start1' => 'browser.exe;browser;NORMAL_PRIOR
+ITY_CLASS',
                         'start2' => 'schedule.exe;schedule "localhost
+:e:\\users\\dbush\\schedule.db";NORMAL_PRIORITY_CLASS',
                         'interval' => '5',
                         'debug' => '1'
                       },
          'scheduledb' => 'e:\\users\\dbush\\schedule.db'
        };
[download]

N.B. One thing to watch out for is scoping your name-value pairs. For all the details about scoping for interpolation, check out Config::General::Interpolated.

--
hiseldl
What time is it? It's Camel Time!

#!/usr/local/bin/perl -w
my %tokens= ( 'general-scheduledb' => 'e:\users\dbush\schedule.db',
              'animal-type' => 'mammal',
              'species' => 'camel',
            );
my $inistring='start2=schedule.exe;schedule "localhost:%general-schedu
+ledb%";NORMAL_PRIORITY_CLASS;%species%';
$inistring =~ s/%([^%]+)%/$tokens{$1}/eg;
print $inistring;
__END__
start2=schedule.exe;schedule "localhost:e:\users\dbush\schedule.db";NO
+RMAL_PRIORITY_CLASS;camel
[download]

Note that this is a naieve implementation - you'll have to add checking that all tokens exist (as this code does not catch typo's in the ini file) for example.

Update: Renamed %values hash to %tokens. Naming a hash values is asking for a headache :).

Also, I missed the part that your token values are in the ini file as well. That means that using my implementation, you would build the %tokens hash from the [general] (or whichever) part of your ini file. However, you probably should start looking at modules for this, as jenda suggests below.

CU
Robartes-

Many thanks (and a ++ tomorrow) to zby, crouchingpenguin, dakkar, robartes, Jenda and hiseldl for their insightful replies.

The solution I have come up with is to use the tie functionality within Config::IniFiles and a slightly modified version of robartes regular expression approach. The while loop handles nested tokens (unlikely as they are in my case).

The following is a code snippet of the approach I intend to use. Comments welcome.

#perl -w
use strict;
use warnings;
use Config::IniFiles;

my ($appname, $cmdline, $priority, $szProcess);

my %config;
tie %config, 'Config::IniFiles', (-file => 'service.ini', -nocase => 1
+);

my @processesToStart 
    = map { $config{'service'}{$_} }
        grep { /^start[0-9]+/ } 
            keys %{$config{'service'}};


foreach $szProcess (@processesToStart) {

    #Break process down into it's parts
    ($appname, $cmdline, $priority) = split /;/, $szProcess;
    
    #Process cmdline
    while ($cmdline =~ s/%([^%]+)-([^%]+)%/$config{lc $1}{lc $2}/eg) 
        {} 

    #Log and run it    already
    print $cmdline, "\n";
    
} 

__END__

Text of service.ini:

[GENERAL]
scheduledb=e:\users\dbush\schedule.db

[SERVICE]
debug=1
interval=5
start1=browser.exe;browser;NORMAL_PRIORITY_CLASS
start2=schedule.exe;schedule "localhost:%general-scheduledb%";NORMAL_P
+RIORITY_CLASS

Output:

browser
schedule "localhost:e:\users\dbush\schedule.gdb"
[download]

The other modules mentioned look interesting (esp. Win32::Daemon::Simple) but I'm afraid I'm up against a bit of a deadline. I also didn't mention that the configuration file must be a standard ini as I share it with some C programs.

Thanks again,
Dom.

I would suggest one little change to the regexp:

while ($cmdline =~ s/%([^%-]+)-([^%]+)%/$config{lc $1}{lc $2}/eg)
[download]

This way it should be quicker since it does not force Perl to backtrack after it slurps up the whole general-scheduledb.

Of course it's not entirely equivalent. If your INI contained %foo-bar-baz%, then your regexp would match it like %(foo-bar)-(baz)% and mine as %(foo)-(bar-baz)%. I don't think it matters.

Jenda

Thanks Jenda - Will do.