#!/usr/bin/perl -w

use strict;

exit main();

sub nextpermute(\@)
{
    my( $vals )= @_;
    my $last= $#{$vals};
    return ""   if  $last < 1;
    my $i= $last-1;             # Find last item not in reverse-sorted order:
    $i--   while  0 <= $i  &&  $vals->[$i] ge $vals->[$i+1];
    return ""   if  -1 == $i;   # Complete reverse sort, done!
    @{$vals}[$i+1..$last]= sort @{$vals}[$i+1..$last]
      if  $vals->[$i+1] gt $vals->[$last];
    my $j= $i+1;                # Find next item that will make us bigger:
    $j++  while  $vals->[$i] ge $vals->[$j];
    @{$vals}[$i,$j]= @{$vals}[$j,$i];
    return 1;
}

sub main
{
    if(  @ARGV  ) {
        my @vals= sort @ARGV;
        do {
            print "@vals\n";
        } until(  ! nextpermute(@vals)  );
        return 0;
    }
    #OR# my @map= (2,1,0);
    for my $zero ( 0..5 ) {
        for my $one ( 0..5-$zero ) {
            my $two= 5-$one-$zero;
            my @val= ( (0)x$zero, (1)x$one, (2)x$two );
            #OR# @val= ( (0)x$two, (1)x$one, (2)x$zero );
            do {
                print "@val\n";
                #OR# print "@map[@val]\n";
            } while(  nextpermute(@val)  );
        }
    }
    return 0;
}