Anonymous Monk has asked for the wisdom of the Perl Monks concerning the following question:
Hi, i'm looking for a less redundant way to say [\$a, \$b, \$c].
$a = "foo";
$b = "bar";
$c = "baz";
@list = \[$a, $b, $c];
foreach(@list) { print $$_ . "\n"; }
Perl appears to set $list[0] to a reference to [$a, $b, $c]. Is there a less redundant way to say [\$a, \$b, \$c] or does the backslash only reference scalars and hashes?
RE: \($a, $b, $c) eq (\$a, \$b, \$c), is \$a, $b, $c eq \$a, \$b, \$c?
by autark (Friar) on Jul 23, 2000 at 04:19 UTC
|
Let's have a look at the '\', '[]' and '()' constructs:
- [$a, $b, $c] is a reference to an array with
three scalar elements.
- \[$a, $b, $c] is a reference to a scalar,
which againg is a reference to an array with three scalar
elements.
- [\$a, \$b, \$c] is a reference to an array with
three scalars. Each of theese three scalars is a reference
to the real scalar.
So using the special braces '[' and ']' creates a reference to an array.
If you use the normal braces '(' and ')' you group things into lists, so:
- ($a, $b, $c) is a list of three scalar elements.
It is not an array, but a list.
- \($a, $b, $c) is a list of three scalar elemnts.
Each of theese three elements is a reference to the real scalar
(that is your value "foo", "bar" and "baz")
- (\$a, \$b, \$c) is excatly the same as \($a, $b, $c).
The '\' operator will distribute over the list.
So if we use the [$a, $b, $c] construct our list @list will contain
one element, namely a reference to an array.
If we on the other hand use the ($a, $b, $c) construct, the list
will contain 3 elements.
So then, an easier way to write [\$a, \$b, \$c] would
be [ \($a, $b, $c) ].
But still, this will not fix your example - I hope you can see the
error in the example, but let's fix it:
$a = "foo";
$b = "bar";
$c = "baz";
@list = \($a, $b, $c);
foreach(@list) { print $$_ . "\n"; }
Autark.
| [reply] [d/l] [select] |
RE: RE: \($a, $b, $c) eq (\$a, \$b, \$c), is \$a, $b, $c eq \$a, \$b, \$c?
by Anonymous Monk on Jul 23, 2000 at 07:37 UTC
|
Thanks, I should RTFM some more. [\($a, $b, $c)] turns out to be what I was looking for.
| [reply] [d/l] |
Re: reference nastiness
by japhy (Canon) on Jul 23, 2000 at 07:01 UTC
|
Ok, if you want @array to have ONE element, which is an
array reference to a list of references to scalars, then:
@array = [ \($a,$b,$c) ];
is for you. But maybe you meant:
@array = \($a,$b,$c);
Regardless, here is something to watch out for:
@array = (1..10);
print scalar @array; # 10
$a = \@array;
print $a; # ARRAY(0x12345)
$b = \(@array);
print $b; # SCALAR(0xabcde)
# is a ref to the last element of @array)
@c = \($a,@array);
print @c; # SCALAR(0x13579)ARRAY(0x12345)
@d = \($a,(@array));
print @d; # SCALAR(0x13579)SCALAR(0x11111)SCALAR(0x11112)...
I hope you see the trend. \(LIST) returns a list of references
to the EXPLICIT elements of the list. \(THIS,(THAT),THOSE)
returns a reference to THIS, expands THAT into a list and then
takes references to each element of the list, and then a
reference to THOSE. It can be icky.
</code>
$_="goto+F.print+chop;\n=yhpaj";F1:eval | [reply] [d/l] [select] |
|
|