You can use the fact that the return value from substr() is an lvalue and do something like:

{
  local *tmp = \substr( $source, $start, $len );
  $tmp =~ y/'//d;
  $tmp =~ y/a-zA-Z0-9\n\|-/ /c;
}
[download]

Damn. That's great. :) And with a little change it's strict compliant and shorter too:

{
    local *_ = \substr $source, $start, $len;
     y/a-zA-Z0-9\n\|-/ /c;
     y/'//d;
}
[download]

Update: changed order of transliterations to account for the deletion of characters causing extra characters to shift in.

Makeshifts last the longest.

Using substr for this is kinda tricky. If one of the earlier ranges contains 's, and you delete them, that screws up the indexes for later ranges. One solution is to substitute a known-not-present char (I used \x7F) for ' whilst processing the ranges and then remove these from the resultant line.

Update:A modified version to deal with replacing 's with spaces at the end of the field rather than deleting them entirely. Makes use of Fletch's neat trick and Aristotle's enhancement to it, now that is possible.

#! perl -sw
use warnings;
use strict;

open( FILE, '<', shift) or die "Couldn't open $::FILE; $!";
@ARGV = map{ [ split(/-/, $_, 2) ] } @ARGV
    or die 'usage $0: file c1-c2 [ c1-c2 [ ... ] ] >modified_file';
while (my $line = <FILE>) {
    for (  @ARGV ) {
        next if $_->[0] > length $line;
        $_->[1] = length $line if $_->[1] > length $line;
        local *_ = \substr($line, $_->[0], $_->[1]-$_->[0] + 1);
        tr[a-zA-Z0-9\n\|\-'][ ]c;
        $_ .= ' ' x tr['][]d;
    }
    print $line;
}
close FILE;
[download]

Original version

++BrowserUK!

I was bitten by my squashing of apostrophes. Because it was a fixed width file, squashing the apostrophes caused the width's to change. I changed the regex to:

s/(.)'(.\B*)/$1$2 /g
[download]

So, that spacing was added for each apostrophe I pulled from any field.

enoch

In that case, there's no need for this line

$tmpString =~ s/(.)'(.)/$1$2/g;            # squash apostrophes
[download]

As the next line

$tmpString =~ tr/a-zA-Z0-9\n\|\-/ /c;    # remove bad characters
[download]

will convert them to spaces anyway?

---

Examine what is said, not who speaks.

The 7th Rule of perl club is -- pearl clubs are easily damaged. Use a diamond club instead.

Using "known nonexistant" characters is just asking for trouble.. it's a practice I've come to regard as a huge red flag. In this particular case and with Perl being Perl, the proper solution is surprising but very neat. Fletch++

Makeshifts last the longest.

Sorry Aristotle. Fletch's (partial) solution, neat as the technique is, falls foul of the fact that deleting the apostrophies in a one range, causes all the subsequent columns to shift.

---

Examine what is said, not who speaks.

The 7th Rule of perl club is -- pearl clubs are easily damaged. Use a diamond club instead.

#!/usr/bin/perl

use strict;
use warnings;

# Store the ranges in a list of hashes.
my @Ranges = ();
foreach my $arg (@ARGV) {
    my ($start, $end) = split(/-/, $arg);
    push @Ranges, { start => $start, end => $end };
}

# Use standard input/output so we can pipe files through it.
while (my $line = <STDIN>) {
    # We go through the columns in reverse so the offsets will be
    # correct.
    foreach my $range (reverse @Ranges) {
        my ($start, $end) = ($range->{start}, $range->{end});
        my $line_len = length($line);
        $end = $line_len if $line_len < $end;
        next if $start > $end;  # Skip out-of-bound ranges

        my $nchars = $end - $start;
        substr($line, $start-1, $end-$start) =
          cleanse(substr($line, $start-1, $end-$start));
    }
    print $line;
}

# Remove apostrophes and other unwanted characters.
sub cleanse {
    my $string = shift;

    $string =~ s/'//g;
    $string =~ tr/a-zA-Z0-9\n\|\-/ /c;

    return $string;
}
[download]

It could use some extra checking on the program arguments (ranges), though.

Arjen

substr($line, $pos1, $pos2) = cleanse(substr($line, $pos1, $pos2));
[download]

The third parameter should be a length, not a position.

substr($line, $pos1, $pos2-$pos1+1) = cleanse(substr($line, $pos1, $po
+s2-$pos1+1));
[download]

Update:Here is some sample code, simplified in its input and output. The "local *tmp" trick by Fletch would also work, but I found it wouldn't pass strict without a "use vars qw($tmp);", so I went back to the simpler temporary variable idea.

use strict;
my @pos = (0,5,15,20);

while(my $line = <>) {
   my $i = $#pos;
   while ($i >= 1) {
       my $pos1 = $pos[$i - 1];
       my $pos2 = $pos[$i];
       my $len = $pos2 - $pos1 + 1;
       my $part = substr( $line, $pos1, $len );
       $part =~ y/'//d;
       $part =~ y/a-zA-Z0-9\n\|-/ /c;
       substr( $line, $pos1, $len ) = $part;
       $i -= 2;
   } # end while $i
   print $line;
} # end while
[download]